PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36

pkgname=pkgpick-git
pkgver=r1.6e86887
pkgrel=1
pkgdesc="Interactive fzf-based TUI package manager for pacman/AUR/Flatpak/npm/pip/cargo/go/pipx, with a Settings and Cleanup menu, EN/RU UI (git version)"
arch=('any')
url="https://github.com/ItzDast/pkgpick"
license=('GPL-3.0-or-later')
depends=('bash' 'fzf' 'pacman')
optdepends=(
    'yay: AUR search/install/update support'
    'paru: alternative AUR helper (used if yay is absent)'
    'flatpak: manage Flatpak apps and runtimes'
    'npm: manage global npm packages'
    'python-pip: manage pip packages'
    'cargo: manage cargo-installed binaries'
    'go: manage go-installed binaries'
    'python-pipx: manage pipx-installed packages'
    'libnotify: desktop notifications for install/remove/update/cleanup'
)
makedepends=('git')
provides=('pkgpick')
conflicts=('pkgpick')
source=("$pkgname::git+https://github.com/ItzDast/pkgpick.git")
sha256sums=('SKIP')

pkgver() {
    cd "$srcdir/$pkgname"
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

package() {
    install -Dm755 "$srcdir/$pkgname/pkgpick.sh" "$pkgdir/usr/bin/pkgpick"
    if [[ -f "$srcdir/$pkgname/pkgnc.svg" ]]; then
        install -Dm644 "$srcdir/$pkgname/pkgnc.svg" "$pkgdir/usr/share/icons/hicolor/scalable/apps/pkgpick.svg"
    fi
}