blob: daf4f745b0ad78940195ae15fff4be5576258bfe (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
|
# Maintainer: Claudia Pellegrino <aur ät cpellegrino.de>
pkgname=pkgx
pkgver=2.7.0
pkgrel=1
pkgdesc='Run Anything'
arch=('x86_64')
url='https://pkgx.sh'
license=('Apache-2.0')
depends=('gcc-libs' 'glibc' 'xz')
makedepends=('cargo')
options=('!lto')
source=(
"${pkgname}-${pkgver}.tar.gz::https://github.com/pkgxdev/pkgx/archive/v${pkgver}.tar.gz"
)
sha512sums=('9d57369324531d18e497388c74d5293b006e124ec0689937b9c3d1de631248fc5c2cc9cad133075ce54524fbd2a8f1b08b10ef1eefcd79470fdaa3df28571ad6')
prepare() {
cd "${srcdir}/${pkgname}-${pkgver}"
echo >&2 'Downloading dependencies'
export RUSTUP_TOOLCHAIN=stable
cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
export RUSTUP_TOOLCHAIN=stable
echo >&2 'Building executable'
cargo build --frozen --release --all-features
}
check() {
cd "${srcdir}/${pkgname}-${pkgver}"
export RUSTUP_TOOLCHAIN=stable
cargo test --frozen --all-features
cd "$(mktemp -d)"
cat > hello.js << 'EOF'
const middle="llo, w"
console.log(`he${middle}orld`);
EOF
stdout="$(
env -i PKGX_DIR="$(pwd)/.pkgx" \
"${srcdir}/${pkgname}-${pkgver}/target/release/pkgx" \
node hello.js
)"
[[ "${stdout}" == 'hello, world' ]]
}
package() {
echo >&2 'Packaging the executable'
install -D -m 755 -t "${pkgdir}/usr/bin" \
"${srcdir}/${pkgname}-${pkgver}/target/release/pkgx"
echo >&2 'Packaging the documentation'
install -D -m 644 -t "${pkgdir}/usr/share/doc/${pkgname}" \
"${srcdir}/${pkgname}-${pkgver}/README.md"
echo >&2 'Packaging the license'
install -D -m 644 -t "${pkgdir}/usr/share/licenses/${pkgname}" \
"${srcdir}/${pkgname}-${pkgver}/LICENSE.txt"
}
|