blob: 06acf1b38e3f08820b6aa43a8441a64921c4d0bf (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
pkgname=planify
_app_id=io.github.alainm23.planify
pkgver=4.11.0
pkgrel=1
pkgdesc="Task manager with Todoist and Nextcloud support"
arch=('x86_64')
url="https://github.com/alainm23/planify"
license=('GPL-3.0-or-later')
depends=(
'evolution-data-server'
'granite7'
'gtksourceview5'
'gxml'
'libadwaita'
'libportal-gtk4'
'webkitgtk-6.0'
)
makedepends=(
'git'
'gobject-introspection'
'meson'
'vala'
)
conflicts=('elementary-planner')
source=("git+https://github.com/alainm23/planify.git#tag=$pkgver")
sha256sums=('28a9c4830057db16d1b658fb345ae39899712059acc98440fa160cec34634fc3')
build() {
arch-meson "$pkgname" build -Dprofile=default
meson compile -C build
}
check() {
meson test -C build --print-errorlogs
appstreamcli validate --no-net "build/data/${_app_id}.appdata.xml" || :
}
package() {
meson install -C build --destdir "$pkgdir"
ln -s "/usr/bin/${_app_id}" "$pkgdir/usr/bin/$pkgname"
}
|