blob: 4b2e6f826547acb1b1bfd2f07907b30e1af913a0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# Maintainer: s3rj1k <evasive dot gyron at gmail dot com>
# Do not forget to run `makepkg --printsrcinfo > .SRCINFO`
_pkgname=plank
_pkgver=0.11.89
pkgname=${_pkgname}-minimal
pkgver=0.11.89+27c7863
pkgrel=2
pkgdesc='Elegant, simple, clean dock (minimal build)'
arch=('x86_64')
url='https://launchpad.net/plank'
license=('GPL3')
depends=('atk' 'bamf' 'cairo' 'gdk-pixbuf2' 'glib2' 'glibc'
'gtk3' 'libgee' 'libwnck3' 'libx11' 'libxfixes' 'libxi' 'pango')
makedepends=('gnome-common' 'gnome-menus' 'git' 'intltool' 'vala')
provides=("${_pkgname}")
conflicts=("${_pkgname}")
source=("git+https://github.com/ricotz/plank.git#tag=${_pkgver}"
'disable-docklets.patch')
sha256sums=('SKIP'
'd46000c57cd19cbcb16737af27fbe4fe748e9e6d17f5c99a8be3845adf5cd983')
pkgver() {
cd "${srcdir}/${_pkgname}"
printf "%s+%s" "${_pkgver}" "$(git rev-parse --short HEAD)"
}
prepare() {
cd ${_pkgname}
sed 's/0.19.6/0.20/' -i configure.ac
# Do not build extra docklets
patch -Np1 -i "$srcdir/disable-docklets.patch"
}
build() {
cd ${_pkgname}
./autogen.sh \
--prefix='/usr' \
--sysconfdir='/etc' \
--disable-apport \
--disable-debug
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
}
package() {
make DESTDIR="${pkgdir}" -C plank install
}
|