PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43

# Maintainer: Aaron Cottle <aaron@aaroncottle.au>

pkgname=plasma-activities-git
pkgver=6.0.80_r1478.g8f90ae8b
_dirver=$(echo $pkgver | cut -d. -f1-3)
pkgrel=1
pkgdesc='Core components for KDE Activities'
arch=(x86_64)
url='https://kde.org/plasma-desktop/'
license=(LGPL-2.0-or-later)
depends=(gcc-libs
         glibc
         kconfig-git
         kcoreaddons-git
         qt6-base)
makedepends=(boost
             doxygen
             extra-cmake-modules-git
             qt6-declarative
             qt6-doc
             qt6-tools)
optdepends=('qt6-declarative: QML bindings')
conflicts=(kactivities kactivities-git plasma-activities)
provides=(kactivities kactivities-git plasma-activities)
source=(git+https://invent.kde.org/plasma/plasma-activities.git)
sha256sums=('SKIP')

pkgver() {
  cd plasma-activities
  _ver="$(grep -m1 'set(PROJECT_VERSION' CMakeLists.txt | cut -d '"' -f2 | tr - .)"
  echo "${_ver}_r$(git rev-list --count HEAD).g$(git rev-parse --short HEAD)"
}

build() {
  cmake -B build -S plasma-activities \
    -DBUILD_TESTING=OFF \
    -DBUILD_QCH=ON
  cmake --build build
}

package() {
  DESTDIR="$pkgdir" cmake --install build
}