blob: 9633e2a8b67e51fba9107dad7833a6a4a2b00ef6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# Maintainer: João Figueiredo <jf dot mundox at gmail dot com>
# Contributor: Antonio Rojas <arojas@archlinux.org>
pkgbase=plasma-desktop-git
pkgname=(plasma-desktop-git knetattach-git)
pkgver=r7992.105369274
pkgrel=1
pkgdesc='KDE Plasma Desktop'
arch=(i686 x86_64)
url='https://projects.kde.org/projects/kde/kde-workspace'
license=(LGPL)
depends=(polkit-kde-agent-git libxkbfile kmenuedit-git systemsettings-git ksysguard-git baloo-git accountsservice)
makedepends=(extra-cmake-modules-git kdoctools-git xf86-input-evdev xf86-input-synaptics xf86-input-libinput xorg-server-devel scim kdesignerplugin kaccounts-integration intltool git)
source=("git+https://github.com/KDE/plasma-desktop.git")
groups=(plasma)
md5sums=('SKIP')
pkgver() {
cd plasma-desktop
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
build() {
cmake -B build -S plasma-desktop \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr \
-DKDE_INSTALL_LIBDIR=lib \
-DKDE_INSTALL_LIBEXECDIR=lib \
-DKDE_INSTALL_USE_QT_SYS_PATHS=ON
cmake --build build
}
package_plasma-desktop-git() {
conflicts=(plasma-desktop)
provides=(plasma-desktop)
depends+=(knetattach)
optdepends=('plasma-nm: Network manager applet'
'powerdevil: power management, suspend and hibernate support'
'kscreen: screen management'
'ibus: kimpanel IBUS support'
'scim: kimpanel SCIM support'
'kaccounts-integration: OpenDesktop integration plugin')
replaces=(user-manager)
DESTDIR="$pkgdir" cmake --install build
# Split knetattach
rm "$pkgdir"/usr/{bin/knetattach,share/applications/org.kde.knetattach.desktop}
}
package_knetattach-git() {
pkgdesc='Wizard which makes it easier to integrate network resources with the Plasma Desktop'
conflicts=(knetattach)
provides=(knetattach)
depends=(kdelibs4support-git)
DESTDIR="$pkgdir" cmake --install build/knetattach
}
|