PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48

# Maintainer: Norbert Preining <norbert@preining.info>
pkgname=plasma-gamemode-git
pkgver=r6.4d60358
pkgrel=1
pkgdesc="Gamemode UI for the Plasma Desktop"
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
arch=('x86_64')
url="https://invent.kde.org/sitter/${pkgname%-git}"
license=('MIT' 'BSD-3-Clause' 'GPL-2.0-only' 'GPL-3.0-only' 'LGPL-3.0-only' 'CC0-1.0')
depends=(
  'kirigami'
  'gcc-libs'
  'gamemode'
  'qt6-base'
  'qt6-declarative'
  'kcoreaddons>=6.0.0'
  'kdbusaddons>=6.0.0'
  'ki18n>=6.0.0'
  'kdeclarative>=6.0.0'
  'libplasma>=6.0.0')

makedepends=('git' 'cmake>=3.16' 'extra-cmake-modules>=6.0.0')
source=(git+${url}.git)
sha256sums=('SKIP')

pkgver() {
	cd "$srcdir/${pkgname%-git}"
	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
	cmake -B build -S "$srcdir/${pkgname%-git}" \
		-DCMAKE_INSTALL_PREFIX='/usr' \
		-DCMAKE_BUILD_TYPE='None' \
		-Wno-dev 
	cmake --build build
}

check() {
	cd build
	ctest --output-on-failure
}

package() {
	DESTDIR="$pkgdir" cmake --install build
	install -Dm 644 -t "${pkgdir}/usr/share/licenses/${pkgname}" "$srcdir/${pkgname%-git}"/LICENSES/*
}