blob: 7cc1273f410412d702998347d2ab15b2fd59d914 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
|
# Maintainer: Shrinivas Vishnu Kumbhar <shrinivas.v.kumbhar@gmail.com>
pkgname=plasma-setup-git
_pkgname=plasma-setup
pkgver=r310.072a568
pkgrel=1
pkgdesc="Initial setup wizard for KDE Plasma (git version)"
arch=('x86_64')
url="https://invent.kde.org/plasma/plasma-setup"
license=('BSD-2-Clause')
depends=(
'gcc-libs'
'glibc'
'qt6-base'
'qt6-declarative'
'qt6-svg'
'kauth'
'kcoreaddons'
'ki18n'
'kpackage'
'kconfig'
'kscreen' # provides KF6Screen
'kwindowsystem' # provides libkworkspace
'plasma-workspace' # provides QML modules
'plasma-desktop' # provides QML modules like kcm_keyboard
)
makedepends=(
'git'
'cmake'
'extra-cmake-modules'
'pkgconf'
'gettext'
)
conflicts=('plasma-setup')
provides=('plasma-setup')
source=("${_pkgname}::git+${url}.git")
md5sums=('SKIP')
pkgver() {
local commit_count short_sha
commit_count=$(git -C "${_pkgname}" rev-list --count HEAD)
short_sha=$(git -C "${_pkgname}" rev-parse --short=7 HEAD)
echo "r${commit_count}.${short_sha}"
}
build() {
cd "${_pkgname}"
cmake -B build \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr
cmake --build build
}
package() {
cd "${_pkgname}"
DESTDIR="${pkgdir}" cmake --install build
# License
install -Dm644 LICENSES/BSD-2-Clause.txt \
"${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
# vim: ts=2 sw=2 et:
|