PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38

# Maintainer: Filipe Nascimento <flipee at tuta dot io>
# Contributor: louis.seubert.ls@gmail.com <Louis Seubert>

pkgname=plasma5-runners-jetbrains-runner
pkgver=1.6.0
pkgrel=1
pkgdesc="A Krunner Plugin which allows you to open your recent projects"
arch=('x86_64')
url="https://github.com/alex1701c/JetBrainsRunner"
license=('LGPL3')
depends=('krunner')
makedepends=('extra-cmake-modules' 'git' 'kcmutils')
install=$pkgname.install
#source=("$pkgname-$pkgver.tar.gz::$url/releases/download/$pkgver/JetBrainsRunnerWithSubmodule.tar.gz")
source=("$pkgname::git+$url#tag=1.6.0"
        "git+https://github.com/alex1701c/jetbrains-api")
sha256sums=('SKIP'
            'SKIP')

prepare() {
    cd $pkgname
    git submodule init
    git config submodule.jetbrains-api.url "$srcdir/jetbrains-api"
    git submodule update
}

build() {
    cd $pkgname
    cmake -B build \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DCMAKE_BUILD_TYPE=Release
    make -C build
}

package() {
    cd $pkgname
    make -C build DESTDIR="$pkgdir" install
}