blob: 4fab8cfd89cbe4ba15817cfa718f33722af82979 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
|
# Maintainer: Claudia Pellegrino <aur ät cpellegrino.de>
pkgname=playdate-sdk
pkgver=2.4.2
pkgrel=1
pkgdesc='SDK for the Playdate console with Lua and C APIs, docs, and a simulator'
arch=('x86_64')
url='https://play.date/dev/'
license=('LicenseRef-SdkLicense')
depends=(
'cairo'
'gdk-pixbuf2'
'glib2'
'gtk3'
'hicolor-icon-theme'
'libpng'
'libxkbcommon'
'pango'
'systemd-libs'
'webkit2gtk'
'xdg-utils'
)
makedepends=('curl' 'jq')
optdepends=(
'python-click: to run the firmware_symbolizer.py utility'
'wayland: for Wayland compatibility'
'zeal: read the Playdate SDK docset offline'
)
options=('!strip')
install="${pkgname}.install"
_url_base='https://download-cdn.panic.com/playdate_sdk/Linux/PlaydateSDK'
source=(
"${pkgname}-${pkgver}.tar.gz::${_url_base}-${pkgver}.tar.gz"
'date.play.simulator.desktop'
'playdate-sdk.install'
'playdate-simulator.shim'
)
sha512sums=(
'bb6b6fb1acd56e290feb194e0b73894528e1fa948e38c6bf940a44dabedf206a37ef116a02ff6bfe345c05dfba2eaea46394b26c18a1c0a778cf0b05ce23dc75'
'7286f35bff63253ff430860ce6a3ce52dfd88bcd90e6dd6cfcbeb90a76b38d2341d4fc428259d00eac7b67c2b94e0319e3d438a67e76e8016d8cd36be1123677'
'ed30d6745f686e985bd54cd23c5a8e9bee95bad7209d065871bf461dc8321dea032583d6a3da9fa9909efca2969dde0954777a55ba42b4974c49ed1993101c92'
'2a909f7d290489e23a5dd1648269e8575e3912057d03649d898fa23a6ff74185bd1080c6366db1b840bce4cb72482c72e218f88bb1aac4d91eec6f89205573cb'
)
noextract=("${pkgname}-${pkgver}.tar.gz")
prepare() {
mkdir -p "${srcdir}/${pkgname}-${pkgver}"
tar -x \
-f "${srcdir}/${pkgname}-${pkgver}.tar.gz" -z \
--no-anchored --wildcards \
-C "${srcdir}/${pkgname}-${pkgver}" \
--exclude='setup.sh' \
--strip-components=1
}
package() {
mkdir -p \
"${pkgdir}/etc/profile.d" \
"${pkgdir}/usr/bin" \
"${pkgdir}/usr/lib/udev/rules.d" \
"${pkgdir}/usr/share/applications" \
"${pkgdir}/usr/share/doc/${pkgname}" \
"${pkgdir}/usr/share/icons/hicolor/scalable/apps/" \
"${pkgdir}/usr/share/licenses/${pkgname}" \
"${pkgdir}/usr/share/mime/packages" \
"${pkgdir}/opt"
echo >&2 'Packaging the license'
install -D -m 644 -t "${pkgdir}/usr/share/licenses/${pkgname}" \
"${srcdir}/${pkgname}-${pkgver}/SDK_LICENSE.md"
echo >&2 'Packaging the README'
install -D -m 644 -t "${pkgdir}/usr/share/doc/${pkgname}" \
"${srcdir}/${pkgname}-${pkgver}/README.md"
echo >&2 'Packaging the icon'
install -D -m 644 -t "${pkgdir}/usr/share/icons/hicolor/scalable/apps" \
"${srcdir}/${pkgname}-${pkgver}/Resources/date.play.simulator.svg"
echo >&2 'Packaging the desktop file'
install -D -m 755 -T \
"${srcdir}/date.play.simulator.desktop" \
"${pkgdir}/usr/share/applications/${pkgname}.desktop"
echo >&2 'Packaging MIME type additions'
install -D -m 644 -t "${pkgdir}/usr/share/mime/packages" \
"${srcdir}/${pkgname}-${pkgver}/Resources/playdate-types.xml"
echo >&2 'Packaging environment additions'
# shellcheck disable=SC2016
cat > "${pkgdir}/etc/profile.d/${pkgname}.sh" \
<<< 'export PLAYDATE_SDK_PATH="${XDG_DATA_HOME:-"${HOME}/.local/share"}/playdate-sdk"'
echo >&2 'Packaging SDK files'
cp -r --preserve=mode -T \
"${srcdir}/${pkgname}-${pkgver}" \
"${pkgdir}/opt/${pkgname}"
echo >&2 'Packaging executables'
ln -s -t "${pkgdir}/usr/bin" \
"/opt/${pkgname}/bin/"{pdc,pdutil}
install -D -m 755 -T \
"${srcdir}/playdate-simulator.shim" \
"${pkgdir}/usr/bin/PlaydateSimulator"
}
|