blob: c92537ca6d78d3441710b98afa2afe5e9745bc59 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
|
# Maintainer: Daniel Egeberg <daniel.egeberg@gmail.com>
# Contributor: Sven-Hendrik Haase <sh@lutzhaase.com>
# Contributor: TingPing <tingping@tingping.se>
pkgname=plex-media-player
pkgver=1.2.0
_gitrev=481
_gitver=b45bbf24
_fullname="$pkgname-$pkgver.$_gitrev-$_gitver"
pkgrel=1
pkgdesc='Next generation Plex Desktop Client'
arch=('i686' 'x86_64')
license=('GPL')
url='https://github.com/plexinc/plex-media-player'
depends=('mpv' 'qt5-webengine>=5.6' 'libcec3' 'sdl2' 'qt5-x11extras' 'qt5-quickcontrols')
makedepends=('cmake' 'conan' 'google-breakpad-git')
source=("$_fullname.tar.gz::https://github.com/plexinc/plex-media-player/archive/v${pkgver}.${_gitrev}-${_gitver}.tar.gz"
'plex-media-player.desktop')
noextract=("plex-web-client-konvergo-$_webclientver.cpp.tbz2")
sha256sums=('c609dbea02f46531e85b75bd94d46c782ddcbd7fc6dddaf6c979393b579be135'
'b03845b761cc18a88252b72d0c83e439006224660444d9174f53cc577f9498b6')
prepare() {
cd "$_fullname"
# All this git version junk fails, just remove it we already have the version
sed -i 's|include(GetGitRevisionDescription)||
s|get_git_head_revision(REFSPEC FULL_GIT_REVISION)||' \
CMakeModules/VersionConfiguration.cmake
sed -i 's|#include <libcec/|#include <libcec3/|' \
src/input/InputCEC.h
sed -i 's|plex/stable|plex/public|' \
conanfile.py
conan_remote="https://conan.plex.tv"
msg2 "Checking for plex conan remote"
if conan remote list | grep -q plex; then
msg2 "plex remote exists for conan"
else
msg2 "Adding ${conan_remote} as a conan remote"
conan remote add plex "$conan_remote"
fi
mkdir -p build
cd build
conan install ..
}
build() {
cd "$_fullname/build"
cmake -DCMAKE_INSTALL_PREFIX='/usr' -DCMAKE_BUILD_TYPE='Release' -DCMAKE_SKIP_RPATH=1 \
-DFULL_GIT_REVISION="$_gitver" -DQTROOT='/usr/share/qt' -DCEC_INCLUDE_DIR=/usr/include/libcec3 \
-DCEC_LIBRARY=/usr/lib/libcec.so.3 ..
make
}
package() {
cd "$_fullname/build"
DESTDIR="$pkgdir" make install
install -Dm644 "$srcdir/plex-media-player.desktop" "$pkgdir/usr/share/applications/plex-media-player.desktop"
install -Dm644 ../resources/images/icon.png "$pkgdir/usr/share/icons/hicolor/256x256/apps/plex-media-player.png"
}
|