blob: a94f039e3c37a1a04b8cfd2e3b573a5c9304bced (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
# Contributor: Igor Dyatlov <dyatlov.igor@protonmail.com>
pkgname=plex-remote
pkgver=1.0.2+5+gc29ef95
pkgrel=3
pkgdesc="A library for easy implementing a remote plex client"
arch=('any')
url="https://github.com/tijder/plex-remote"
license=('MIT')
depends=('python')
makedepends=(
'git'
'python-build'
'python-installer'
'python-setuptools'
'python-wheel'
)
_commit=c29ef9549c166902e53b3a1b603b365d70ebdf93 # master
source=("git+https://github.com/tijder/plex-remote.git#commit=${_commit}")
sha256sums=('3e15b001afe3a09257bb1e46b54cd834aca4def08bd369cc03d9a50b5c9bb6ec')
pkgver() {
cd "$pkgname"
git describe --tags --abbrev=7 | sed 's/^v//;s/-/+/g'
}
prepare() {
git -C "$pkgname" clean -dfx
}
build() {
cd "$pkgname"
python -m build --wheel --no-isolation
}
package() {
cd "$pkgname"
python -m installer --destdir="$pkgdir" dist/*.whl
install -Dm644 LICENSE.md -t "$pkgdir/usr/share/licenses/$pkgname/"
}
|