PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57

# Maintainer: Sven Karsten Greiner <sven@sammyshp.de>

pkgname=plotjuggler-git
pkgver=3.17.1.r0.gddcbd05b
pkgrel=1
pkgdesc="The Time Series Visualization Tool that you deserve. Without ROS dependencies."
arch=('x86_64')
url="https://github.com/PlotJuggler/PlotJuggler"
license=('MPL-2.0')
depends=(
    'arrow'
    'binutils'
    'fmt'
    'lua'
    'mosquitto'
    'nlohmann-json'
    'protobuf'
    'python'
    'qt5-base'
    'qt5-multimedia'
    'qt5-serialport'
    'qt5-svg'
    'qt5-websockets'
    'qt5-x11extras'
    'zeromq'
)
makedepends=(
    'cmake'
    'clang'
    'git'
)
provides=('plotjuggler')
conflicts=('plotjuggler')
source=(
    'git+https://github.com/PlotJuggler/PlotJuggler.git'
)
sha256sums=(
    'SKIP'
)

pkgver() {
    cd PlotJuggler
    git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
    cd "PlotJuggler"
    cmake -S . -B build \
        -DCMAKE_INSTALL_PREFIX="/usr" \
        -DCMAKE_CXX_FLAGS="$CXXFLAGS -ffat-lto-objects"
    cmake --build build
}

package() {
    cd "PlotJuggler"
    DESTDIR="${pkgdir}" cmake --install build
}