blob: 2f6fe98497b4c2f6c96af27e4dd8ade386e588f3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Maintainer: Mubashshir <ahmubashshir@gmail.com>
# from: github
# what: alexhuntley/Plots
# deps: setuptools
pkgname=plots
_name=Plots
pkgver=0.8.4
pkgrel=1
pkgdesc="A graph plotting app for GNOME"
arch=(any)
url="https://github.com/alexhuntley/Plots"
license=('GPL')
depends=(
'gtk3'
'otf-latinmodern-math'
'python-freetype-py' #auto-deps
'python-jinja' #auto-deps
'python-lark-parser' #auto-deps
'python-numpy' #auto-deps
'python-pyglm' #auto-deps
'python-gobject' #auto-deps
'python-opengl' #auto-deps
)
makedepends=('python-setuptools')
checkdepends=('python-pytest')
source=(
"$pkgname-$pkgver.tar.gz::https://github.com/alexhuntley/$_name/archive/v$pkgver.tar.gz"
)
sha256sums=('7dad515899ea2a224215d524b848b8e0c166452e9dddb79e80c4b3f85d569255')
build() {
cd "$_name-$pkgver"
python setup.py build
}
check() {
cd "$_name-$pkgver"
python setup.py test
}
package() {
cd "$_name-$pkgver"
rm -rf build/lib/tests
python setup.py install --root="$pkgdir" --optimize=1 --skip-build
install -D -t "$pkgdir/usr/share/help/C/plots/" help/C/*
install -Dm644 res/com.github.alexhuntley.Plots.svg "$pkgdir/usr/share/icons/hicolor/scalable/apps/plots.svg"
install -Dm644 res/com.github.alexhuntley.Plots-symbolic.svg "$pkgdir/usr/share/icons/hicolor/symbolic/apps/plots-symbolic.svg"
install -Dm644 res/com.github.alexhuntley.Plots.desktop "$pkgdir/usr/share/applications/plots.desktop"
sed -Ei 's/^(Icon=).*$/\1plots/' "$pkgdir/usr/share/applications/plots.desktop"
}
|