PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60

# Maintainer: Ahmad Hasan Mubashshir <ahmubashshir@gmail.com>
# from: git

pkgname=plots-git
pkgver=0.8.5.r66.g819d29d
pkgrel=1
pkgdesc="A graph plotting app for GNOME"
arch=('any')
url="https://github.com/alexhuntley/Plots/"
license=('GPL')
depends=(
	'gtk3'
	'libhandy'
	'python-gobject'
	'python-opengl'
	'python-jinja'
	'python-numpy'
	'python-lark-parser'
	'otf-latinmodern-math'
	'python-freetype-py'
	'python-pyglm'
)

makedepends=('python-setuptools')
checkdepends=('python-pytest')
provides=('plots')
conflicts=('plots')
source=(
	"plots::git+https://github.com/alexhuntley/Plots.git"
)
md5sums=('SKIP')

pkgver()
{
	cd "$srcdir/plots"
	( set -o pipefail
		git describe --tags --long 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/^v//' ||
		printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
	)
}

build() {
	cd plots
	python setup.py build
}

check() {
	cd plots
	python setup.py test
}
package() {
	cd plots
	rm -rf build/lib/tests
	python setup.py install --root="$pkgdir" --optimize=1 --skip-build
	install -D -t "$pkgdir/usr/share/help/C/plots/" help/C/*
	install -Dm644 res/com.github.alexhuntley.Plots.svg "$pkgdir/usr/share/icons/hicolor/scalable/apps/plots.svg"
	install -Dm644 res/com.github.alexhuntley.Plots-symbolic.svg "$pkgdir/usr/share/icons/hicolor/symbolic/apps/plots-symbolic.svg"
	install -Dm644 res/com.github.alexhuntley.Plots.desktop "$pkgdir/usr/share/applications/plots.desktop"
	sed -Ei 's/^(Icon=).*$/\1plots/' "$pkgdir/usr/share/applications/plots.desktop"
}