blob: f5edb0931e78c342dfb5539aa31c4f2d2ab68d7e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
|
# Maintainer: Viktor Drobot (aka dviktor) linux776 [at] gmail [dot] com
pkgname=pmemd
pkgver=20
_toolsver=20
_gccver=9.3.0
pkgrel=3
pkgdesc="PMEMD module of AMBER software package"
url="http://ambermd.org/"
license=(custom)
arch=(x86_64)
depends=(ambertools)
makedepends=('cmake>=3.8.1' make gcc9 flex bison patch tcsh imake openmpi-gcc9 'cuda>=7.5')
optdepends=('openmpi-gcc9: MPI support'
'cuda: GPU acceleration support'
'plumed: metadynamics support'
'plumed-mpi: metadynamics support with MPI'
'vmd: visualize trajectories')
options=(staticlibs !buildflags)
# Due to licensing issues you must register and download AmberTools package from AmberMD url and put it in directory with PKGBUILD.
# Moreover, you MUST purchase Amber package from AmberMD group and also place it in directory with PKGBUILD.
source=("local://AmberTools${_toolsver}.tar.bz2"
"local://Amber${pkgver}.tar.bz2"
"pmemd"
"pmemd.MPI"
"pmemd.cuda"
"pmemd.cuda.MPI")
md5sums=('8c1fe81833796a9cb823019e02c522e0'
'559d5b7b872344c268a62ebd5d33f71d'
'9a4dab06ab1ba04f12950b26ec5285e5'
'a9a440a1e0c1b1aee7f356869d03b18e'
'69c5d2bdc5e1f6e854c640db7ce1c2ff'
'451eec2b6fa7572f6b61104709588824')
prepare() {
cd ${srcdir}/amber${pkgver}_src
./update_amber --update
}
build() {
cd ${srcdir}/amber${pkgver}_src/build
export AMBER_PREFIX="${srcdir}"
CC=gcc-9 CXX=g++-9 FC=gfortran-9 cmake $AMBER_PREFIX/amber${pkgver}_src \
-DCMAKE_INSTALL_PREFIX=/opt/amber \
-DCOMPILER=MANUAL \
-DMPI=TRUE -DCUDA=TRUE \
-DOPENMP=TRUE \
-DINSTALL_TESTS=FALSE \
-DDOWNLOAD_MINICONDA=FALSE \
-DFORCE_DISABLE_LIBS="plumed" \
-DFORCE_INTERNAL_LIBS="arpack;xblas;netcdf;netcdf-fortran;pnetcdf;fftw;boost;mpi4py" \
2>&1 | tee cmake.log
cd src
make
}
package() {
mkdir -p ${pkgdir}/opt/amber
# install stuff
cd ${srcdir}/amber${pkgver}_src/build/src
make DESTDIR=${pkgdir} install
# install wrappers
install -Dm755 ${srcdir}/pmemd ${pkgdir}/usr/bin/pmemd
install -Dm755 ${srcdir}/pmemd.MPI ${pkgdir}/usr/bin/pmemd.MPI
install -Dm755 ${srcdir}/pmemd.cuda ${pkgdir}/usr/bin/pmemd.cuda
install -Dm755 ${srcdir}/pmemd.cuda.MPI ${pkgdir}/usr/bin/pmemd.cuda.MPI
}
|