blob: 94c179c36a644633e045989628f8c874a559b3c4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Maintainer: Fabian Bornschein <fabiscafe-cat-mailbox-dog-org>
pkgname=pokemon-revolution-online-bin
__LIN_DESKTOP_ASSET_VER=0.4.1
__PROCLIENT_VER=20220112
pkgver=${__PROCLIENT_VER}+${__LIN_DESKTOP_ASSET_VER}
pkgrel=1
pkgdesc="A free-to-play, fan-made, MMO game that is predicated around the official Pokémon games."
arch=('x86_64')
url="https://pokemonrevolution.net"
license=('custom')
depends=('vulkan-driver' 'opengl-driver')
makedepends=('git')
optdepends=('gtk2: required for the Unity ScreenSelector plugin')
conflicts=('pokemon-revolution-online')
source=("git+https://gitlab.com/fabiscafe/pro_assets_lin_desktop.git#tag=${__LIN_DESKTOP_ASSET_VER}"
"PROClient_linux-${__PROCLIENT_VER}.zip::https://ddl.pokemonrevolution.net/PROClient_linux.zip"
)
sha512sums=('SKIP'
'552b2dff0db7d1d4e3925d2c64fb887d8f28987ca84dcfc532714294ac92c9fa0acbc0bb61746f41a14bb7f05f9690d4f75ce715d75dbace0a609e9f9ba6d0a4')
package() {
cd "PROClient"
# As of wishes from the license, don't touch the original, extracted files.
# Instead copy the structure and files 1:1 with better permissions.
# Everything outside of /opt/PROClient is provided by
# https://gitlab.com/fabiscafe/pro_assets_lin_desktop.git
# Folderstructure
/usr/bin/find . \
-type d \
-exec \
/usr/bin/install -dm755 "${pkgdir}/opt/PROClient/{}" \;
# Gamedata and binaries
/usr/bin/find . \
-type f \
! -name "PROClient.x86_64" \
-exec \
/usr/bin/install -m644 "{}" "${pkgdir}/opt/PROClient/{}" \;
/usr/bin/install -m755 "${srcdir}/PROClient/PROClient.x86_64" "${pkgdir}/opt/PROClient/PROClient.x86_64"
# Integration (by pro_assets_lin_desktop.git)
/usr/bin/install -D -m644 "${srcdir}/pro_assets_lin_desktop/net.pokemonrevolution.svg" \
"${pkgdir}/usr/share/pixmaps/net.pokemonrevolution.svg"
/usr/bin/install -D -m644 "${srcdir}/pro_assets_lin_desktop/net.pokemonrevolution.desktop" \
"${pkgdir}/usr/share/applications/net.pokemonrevolution.desktop"
/usr/bin/install -D -m755 "${srcdir}/pro_assets_lin_desktop/PROClient" \
"${pkgdir}/usr/bin/PROClient"
/usr/bin/install -D -m644 "${srcdir}/pro_assets_lin_desktop/pkg_copyright" \
"${pkgdir}/usr/share/licenses/pokemon-revolution-online-bin/copyright"
}
|