blob: d9a21064915b9b82ae5d0c869cd9ae7dbc2d6a95 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
|
# Maintainer: Fabian Bornschein <fabiscafe@archlinux.org>
pkgname=pokemon-revolution-online-bin
__PROCLIENT_VER=20240106
pkgver=20240106+asset0.5
pkgrel=1
pkgdesc="A free-to-play, fan-made, MMO game that is predicated around the official Pokémon games."
arch=('x86_64')
url="https://pokemonrevolution.net"
license=('custom')
depends=(
'vulkan-driver'
'opengl-driver')
makedepends=('git')
__LIN_DESKTOP_ASSET_COMMIT=da21f5467ed5b29d59cc67df3ccdc7686d763406 #tag 0.5
source=("git+https://gitlab.com/fabiscafe/pro_assets_lin_desktop.git#commit=${__LIN_DESKTOP_ASSET_COMMIT}"
"PROClient_linux-${__PROCLIENT_VER}.tar.gz::https://ddl.pokemonrevolution.net/PROClient_linux.tar.gz")
sha512sums=('SKIP'
'327057471e300b217b94f6e8eb9c4b0c7df6064f5f12759bbffc41f93ef34b00b4fcd1a9d966455041c99a0314e234274bd5d300650e482cc3b95fbf6571c53e')
pkgver() {
cd pro_assets_lin_desktop
printf "${__PROCLIENT_VER}+asset$(git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g')"
}
package() {
cd "PROClient"
# As of wishes from the license, don't touch the original, extracted files.
# Instead copy the structure and files 1:1 with better permissions.
# Everything outside of /opt/PROClient is provided by
# https://gitlab.com/fabiscafe/pro_assets_lin_desktop.git
# Folderstructure
/usr/bin/find . \
-type d \
-exec \
/usr/bin/install -dm755 "${pkgdir}/opt/PROClient/{}" \;
# Gamedata and binaries
/usr/bin/find . \
-type f \
! -name "PROClient.x86_64" \
-exec \
/usr/bin/install -m644 "{}" "${pkgdir}/opt/PROClient/{}" \;
/usr/bin/install -m755 "${srcdir}/PROClient/PROClient.x86_64" "${pkgdir}/opt/PROClient/PROClient.x86_64"
# Integration (by pro_assets_lin_desktop.git)
/usr/bin/install -D -m644 "${srcdir}/pro_assets_lin_desktop/net.pokemonrevolution.PROClient.svg" \
"${pkgdir}/usr/share/pixmaps/net.pokemonrevolution.PROClient.svg"
/usr/bin/install -D -m644 "${srcdir}/pro_assets_lin_desktop/net.pokemonrevolution.PROClient-symbolic.svg" \
"${pkgdir}/usr/share/pixmaps/net.pokemonrevolution.PROClient-symbolic.svg"
/usr/bin/install -D -m644 "${srcdir}/pro_assets_lin_desktop/net.pokemonrevolution.PROClient.desktop" \
"${pkgdir}/usr/share/applications/net.pokemonrevolution.PROClient.desktop"
/usr/bin/install -D -m755 "${srcdir}/pro_assets_lin_desktop/PROClient" \
"${pkgdir}/usr/bin/PROClient"
/usr/bin/install -D -m644 "${srcdir}/pro_assets_lin_desktop/pkg_copyright" \
"${pkgdir}/usr/share/licenses/pokemon-revolution-online-bin/copyright"
}
|