blob: 15d2bd7f69911c982d4ed489d71bfbf58f9f12db (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# Maintainer: blacktav <blacktav at gmail dot com>
# Contributor: based on unknown abandoned pokerth-final from 2012-12-27
# Patches: xx55tt
pkgname=pokerth
pkgver=1.1.2
pkgrel=19
pkgdesc="Client to online Poker game written in C++/QT"
arch=('i686' 'x86_64')
url="http://www.pokerth.net/"
license=('GPL' 'custom')
depends=('curl' 'boost-libs' 'gsasl' 'protobuf'
'qt5-base' 'sdl_mixer' 'tinyxml')
makedepends=('boost')
source=(https://sourceforge.net/projects/$pkgname/files/$pkgname/$pkgver/$pkgname-$pkgver.tar.gz
${pkgname}-${pkgver}.patch
${pkgname}-${pkgver}.patch.2019
${pkgname}-${pkgver}.patch.2020)
md5sums=('8fd7d7fc7ece17315e58aa3240dd4586'
'0ef5541fc6008dfb2521dcab47afb659'
'50d427bd8afc57fb61e186de6c4e5601'
'e5bf2357733b4508737f8271f3c1e65f')
prepare() {
cd "$srcdir/$pkgname-$pkgver-rc"
# ---< required for v1.1.2 >--------------------------------------------------
# these changes should be incorporated in next release ~feb-2018
patch -Np1 -i "${srcdir}/pokerth-1.1.2.patch"
# ----------------------------------------------------------------------------
# changes to permit building with boost 1.70
patch -Np1 -i "${srcdir}/pokerth-1.1.2.patch.2019"
# ----------------------------------------------------------------------------
# change to permit building with boost 1.74
# see also DEFINE+="BOOST_BIND_GLOBAL_PLACEHOLDERS" in build below
patch -Np1 -i "${srcdir}/pokerth-1.1.2.patch.2020"
# ----------------------------------------------------------------------------
# good idea to do this at all times
protoc -I=$srcdir/$pkgname-$pkgver-rc/ --cpp_out=$srcdir/$pkgname-$pkgver-rc/src/third_party/protobuf/ $srcdir/$pkgname-$pkgver-rc/pokerth.proto $srcdir/$pkgname-$pkgver-rc/chatcleaner.proto
}
build() {
cd "$srcdir/$pkgname-$pkgver-rc"
# QMAKE_CFLAGS_ISYSTEM workaround to prevent generation of "-isystem /usr/include"
qmake CONFIG+="client" DEFINES+="BOOST_BIND_GLOBAL_PLACEHOLDERS" QMAKE_CFLAGS_ISYSTEM= -spec linux-g++ ${pkgname}.pro
make
}
package() {
cd "$srcdir/$pkgname-$pkgver-rc"
make INSTALL_ROOT="$pkgdir" install
install -D pokerth "$pkgdir/usr/bin/pokerth"
install -D -m644 docs/pokerth.1 "$pkgdir/usr/share/man/man1/pokerth.1"
install -D -m644 data/data-copyright.txt "$pkgdir/usr/share/licenses/pokerth/data-copyright.txt"
rm -f "$pkgdir/usr/share/pokerth/data/data-copyright.txt"
}
|