blob: a8e1ca2004c7c3b5710c4d996a25125dda2c29c0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Maintainer: Vyacheslav Konovalov <🦀vk@protonmail.com>
pkgname=polaris
pkgver=0.13.5
_webver=build-51
pkgrel=1
pkgdesc='Music streaming application, designed to let you enjoy your music collection from any computer or mobile device'
arch=('x86_64')
url='https://github.com/agersant/polaris'
license=('MIT')
depends=('openssl' 'sqlite')
makedepends=('cargo' 'npm')
backup=('etc/polaris/config.toml')
source=(
"https://github.com/agersant/polaris/archive/$pkgver.tar.gz"
"https://github.com/agersant/polaris-web/archive/$_webver.tar.gz"
'config.toml'
'polaris.tmpfiles'
'polaris.sysusers'
'polaris.service'
)
sha512sums=(
'968d012337102b1fd178940b2bcf1976e479efa37cbc68775e97800afbcf37a85048d5f988142057c067c69a25058b4e9aaacdc8bf362c2c8a31077ca909670e'
'a4f0dccc2b7eff896253b7bc9ac9edc26e081963a7dd4d189e026e12cc2aab3bb44387e15fba314ccf05149dbec594e56688e8a4809558b1ff2b0e6fede0b5d9'
'2e4fe41b394508cb6a767a5b5732745d48d08c32967f66696934346e78f42de529ae47b3102d269198781c04f76cdf8c15555f5090f6b08bce09b2a0c13779ff'
'ca327748ca9c297a8facede92b6e8e8aa0c040228b1d84c5754b5f10a8e8a60a8a13b4e4db501b1bdd3c24ff13bec6ec0eec7dc3f2881ba6de72bf095e936644'
'970c9e0e7fbd48a51a644da1ccb9563ba463c1b30bc60581f226c155a7c6b443bdeb1a4b272550a6d19bfc922f2ec6715364e55f6c589e4c87abc3c12b67a9fa'
'4e3521cb664f5cc47551e38fab8d979f0de0be62c02f301b48bd0ddfc48479ea00f0309db1bd293192fc75d31968c7ea88dddaa5d91b8304558d7d6baef016a9'
)
install='polaris.install'
build() {
# Build the server
cd $pkgname-$pkgver
cp res/unix/Makefile .
make PREFIX=/usr LOCALSTATEDIR=/var RUNSTATEDIR=/run build
# Build the client
cd "$srcdir/polaris-web-$_webver"
npm install --cache "$srcdir/npm-cache"
npm run production
}
# BUG: some tests are broken (last checked 2021-05-27)
# check() {
# cd $pkgname-$pkgver
# cargo test --release --locked
# }
package() {
install -Dm644 config.toml -t "$pkgdir/etc/polaris"
install -Dm644 polaris.service -t "$pkgdir/usr/lib/systemd/system"
install -Dm644 polaris.tmpfiles "$pkgdir/usr/lib/tmpfiles.d/$pkgname.conf"
install -Dm644 polaris.sysusers "$pkgdir/usr/lib/sysusers.d/$pkgname.conf"
cd $pkgname-$pkgver
install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
install -Dm755 target/release/polaris -t "$pkgdir/usr/bin"
install -dm755 "$pkgdir/usr/share/polaris"
cp -rT "$srcdir/polaris-web-$_webver/dist" "$pkgdir/usr/share/polaris/web"
cp -rT docs/swagger "$pkgdir/usr/share/polaris/swagger"
}
|