blob: 1a39a450d1143d4b1915730e3e7b5c7f6e954267 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# Maintainer: Yellow <yellow@example.com>
# Contributor: Elijah Gregg <lovetocode999@tilde.team>
# Contributor: Lenny McLennington <lennymclennington@protonmail.com>
# Contributor: Miko <mikoxyzzz@gmail.com>
# Contributor: Cheru Berhanu <aur attt cheru doot dev>
pkgname=polymc
pkgver=1.0.5
pkgrel=1
pkgdesc="Minecraft launcher with ability to manage multiple instances."
arch=('i686' 'x86_64')
url="https://github.com/PolyMC/PolyMC"
license=('GPL3')
depends=('java-runtime' 'libgl' 'qt5-base' 'zlib')
provides=('polymc')
conflicts=('polymc' 'multimc')
makedepends=('cmake' 'git' 'java-environment')
optdepends=('glfw: to use system GLFW libraries'
'openal: to use system OpenAL libraries'
'visualvm: Profiling support'
'xorg-xrandr: for older minecraft versions'
)
source=("PolyMC::git+https://github.com/PolyMC/PolyMC#commit=1cc7a193c27855bd30a90cb24ad678064a26022d" # 1.0.5
"git+https://github.com/MultiMC/libnbtplusplus#commit=dc72a20b7efd304d12af2025223fad07b4b78464"
"git+https://github.com/PolyMC/quazip#commit=c9ef32de19bceb58d236f5c22382698deaec69fd")
sha256sums=('SKIP'
'SKIP'
'SKIP')
prepare() {
cd "${srcdir}/PolyMC"
git submodule init
git config submodule.libnbtplusplus.url "${srcdir}/libnbtplusplus"
git config submodule.quazip.url "${srcdir}/quazip"
git submodule update
}
build() {
cd "${srcdir}/PolyMC"
mkdir -p build
cd build
cmake -DCMAKE_BUILD_TYPE=None \
-DCMAKE_INSTALL_PREFIX="/usr" \
-DLauncher_LAYOUT=lin-system \
-DLauncher_APP_BINARY_NAME="${pkgname}" \
-DLauncher_SHARE_DEST_DIR="share/${pkgname}" \
..
make
}
check() {
cd "${srcdir}/PolyMC/build"
make test
}
package() {
cd "${srcdir}/PolyMC/build"
make install DESTDIR="${pkgdir}"
install -D "${srcdir}/PolyMC/build/libLauncher_quazip.so" "${pkgdir}/usr/lib/libLauncher_quazip.so"
install -D "${srcdir}/PolyMC/build/libLauncher_nbt++.so" "${pkgdir}/usr/lib/libLauncher_nbt++.so"
}
|