summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 1eb5fc75f36762a3ab6521861bb3d5f24c4d4ec9 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
# Maintainer: Victor Zamanian <victor.zamanian@gmail.com>

_pkgname=pomotroid
pkgname="${_pkgname}-bin"
pkgver=0.10.0
pkgrel=1
pkgdesc="Simple and visually-pleasing Pomodoro timer"
arch=('x86_64')
url="https://github.com/Splode/pomotroid"
license=('MIT')
depends=('zlib' 'hicolor-icon-theme')
options=(!strip)
source_x86_64=(
  "${url}/releases/download/v${pkgver}/${_pkgname}-${pkgver}-linux.tar.gz"
  "https://raw.githubusercontent.com/Splode/pomotroid/master/LICENSE"
  "${_pkgname}.desktop"
  "${_pkgname}.png"
)
md5sums_x86_64=('9fe41dec9b0087ab79191e9ba4afcae7'
                '98368ac76439a0812a58d0a586b28ed1'
                '4276e15ba2505a034a80a272e9c9f0ed'
                '81ad82d2a70c058cb80a6ee7679c5f66')

package() {
    # Copy everything from tar
    install -dm755 "${pkgdir}/opt"
    cp -a "${srcdir}/${_pkgname}-${pkgver}-linux/" "${pkgdir}/opt/${_pkgname}"
    chmod 755 "${pkgdir}/opt/${_pkgname}"

    # Copy license
    install -Dm644 "${srcdir}/LICENSE" "${pkgdir}/opt/${_pkgname}/LICENSE"

    # Copy desktop file
    install -Dm644 "${srcdir}/${_pkgname}.desktop" \
      "${pkgdir}/usr/share/applications/${_pkgname}.desktop"

    # Icon images
    install -dm755 "${pkgdir}/usr/share/icons/hicolor/256x256/apps"
    install -Dm644 -t "${pkgdir}/usr/share/icons/hicolor/256x256/apps" \
      "${srcdir}/${_pkgname}.png"

    # Symlink executable
    install -dm755 "${pkgdir}/usr/bin"
    ln -s "/opt/${_pkgname}/${_pkgname}" "${pkgdir}/usr/bin/${_pkgname}"

    # Symlink license
    install -dm755 "${pkgdir}/usr/share/licenses/${_pkgname}"
    ln -s "/opt/${_pkgname}/LICENSE" "$pkgdir/usr/share/licenses/${_pkgname}"
}