PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58

# Maintainer: Carl George < arch at cgtx dot us >

pkgname='pop-gtk-theme'
pkgver=1.2.1
pkgrel=1
pkgdesc='System76 Pop GTK+ Theme (GNOME, Budgie, XFCE, MATE)'
arch=('any')
url='https://github.com/system76/pop-gtk-theme'
license=('GPL2' 'CCPL:by-sa')
makedepends=(
    'autoconf'
    'automake'
    'inkscape'
    'gdk-pixbuf2>=2.32.2'
    'glib2>=2.48.0'
    'librsvg>=2.40.13'
    'libsass>=3.3.6'
    'libxml2'
    'pkg-config'
    'sassc>=3.3.2'
    'parallel'
)
source=("$url/archive/v$pkgver/$pkgname-$pkgver.tar.gz")
sha256sums=('1b637fc557362943507210d5bc1f6af3baefed87828d2ad47013fd823c906784')

prepare() {
    cd "$pkgname-$pkgver"
    ./autogen.sh \
        --disable-flashback \
        --disable-unity \
        --enable-nokto \
        --enable-chrome \
        --enable-plank \
        --enable-telegram \
        --enable-parallel
}

build() {
    cd "$pkgname-$pkgver"
    make
}

package() {
    depends=(
        'gtk2>=2.24.30'
        'gtk3>=3.18.9'
        'gdk-pixbuf2>=2.24.30'
        'gtk-engine-murrine>=0.98.1'
    )
    optdepends=(
        'gnome-shell>=3.18.3: GNOME Shell'
        'budgie-desktop>=10.2.7: Budgie desktop'
        'xfdesktop>=4.12.2: XFCE desktop'
        'mate-desktop>=1.14.0: MATE desktop'
    )
    cd "$pkgname-$pkgver"
    make DESTDIR="$pkgdir" install
}