summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 76270d53e0f27d2233ef6be73a33d7ff2b5f0448 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=popt-git
pkgver=1.18.r46.g1ffb350
pkgrel=1
pkgdesc="C library for parsing command line parameters"
arch=('i686' 'x86_64')
url="https://github.com/rpm-software-management/popt"
license=('MIT')
depends=('glibc')
makedepends=('git')
provides=('popt')
conflicts=('popt')
options=('staticlibs')
source=("git+https://github.com/rpm-software-management/popt.git")
sha256sums=('SKIP')


pkgver() {
  cd "popt"

  git describe --long --tags | sed 's/^popt-//;s/-release//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "popt"

  autoreconf -fi
  ./configure \
    --prefix="/usr"
  make
}

check() {
  cd "popt"

  make check
}

package() {
  cd "popt"

  make DESTDIR="$pkgdir" install
  install -Dm644 "COPYING" -t "$pkgdir/usr/share/licenses/popt"
}