blob: 622d04b528c6dae6f1a685ab360973090ce5516c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: Ben Brooks <ben@bbrks.me>
# PRs/Issues: https://github.com/bbrks/aur-portainer-bin
pkgname=portainer-bin
pkgver=2.11.0
pkgrel=1
epoch=
pkgdesc="A lightweight docker management UI"
arch=('armv6h' 'armv7h' 'aarch64' 'x86_64')
url="https://github.com/portainer/portainer"
license=('custom:zlib')
provides=('portainer')
conflicts=('portainer')
depends=('docker' 'docker-compose')
optdepends=()
makedepends=()
source=("portainer.service"
"portainer.png"
"portainer.desktop"
"portainer-${pkgver}-src.tar.gz::${url}/archive/${pkgver}.tar.gz")
source_x86_64=("${url}/releases/download/${pkgver}/portainer-${pkgver}-linux-amd64.tar.gz")
source_aarch64=("${url}/releases/download/${pkgver}/portainer-${pkgver}-linux-arm64.tar.gz")
source_armv6h=("${url}/releases/download/${pkgver}/portainer-${pkgver}-linux-arm.tar.gz")
source_armv7h=("${url}/releases/download/${pkgver}/portainer-${pkgver}-linux-arm.tar.gz")
sha256sums=('08603677ac3c01235fcd740892bfae9277bd163b908f62b22e6e7edfdb61976c'
'8cb50d80f1463cef0a907b7f26ec6387b792182959f51f8cd19dcb6f955b886e'
'82f7fca2af76e52147397c3b7b07091b72c1be7c82da6bc47e53001306759635'
'4ea3dac13b4b739ceed52b5decdc6e801bb8e90fb2ed1a0383302314383135a3')
sha256sums_armv6h=('49e2f628b9021221849dceb7ecb43184785a95ffa7e57f79f01e1d8a64c75ac4')
sha256sums_armv7h=('49e2f628b9021221849dceb7ecb43184785a95ffa7e57f79f01e1d8a64c75ac4')
sha256sums_aarch64=('44b69d824241a00a03b9bdf42778a3bd3bbd0ce5c8e8816ffa5058a6d79fdc0b')
sha256sums_x86_64=('8e0c90524ba1a2a7e5e788d0dfaa41aa84dc22c5e5f0f97763debaef6d32e608')
package() {
install -Dm644 "${srcdir}/portainer-${pkgver}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
install -Dm755 "${srcdir}/portainer/portainer" "${pkgdir}/usr/bin/portainer"
mkdir -p "${pkgdir}/usr/share/portainer"
cp -rip "${srcdir}/portainer/public" "${pkgdir}/usr/share/portainer/public"
install -Dm644 "portainer.png" "${pkgdir}/usr/share/icons/hicolor/scalable/apps/portainer.png"
install -Dm644 "portainer.desktop" "${pkgdir}/usr/share/applications/portainer.desktop"
install -Dm644 "portainer.service" "${pkgdir}/usr/lib/systemd/system/portainer.service"
ln -s "/usr/bin/docker-compose" "${pkgdir}/usr/share/portainer/docker-compose"
}
|