blob: 0d2c649d1380fcb148030e0eedc3f7e8ae5806f2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# Maintainer: Ben Brooks <ben@bbrks.me>
# PRs/Issues: https://github.com/bbrks/aur-portainer-bin
pkgname=portainer-bin
pkgver=2.14.1
pkgrel=2
epoch=1
pkgdesc="A lightweight docker management UI"
arch=('armv6h' 'armv7h' 'aarch64' 'x86_64')
url="https://github.com/portainer/portainer"
license=('custom:zlib')
provides=('portainer')
conflicts=('portainer')
depends=('docker' 'docker-compose')
optdepends=()
makedepends=()
source=("portainer.service"
"portainer.png"
"portainer.desktop"
"portainer-${pkgver}-src.tar.gz::${url}/archive/${pkgver}.tar.gz")
source_x86_64=("${url}/releases/download/${pkgver}/portainer-${pkgver}-linux-amd64.tar.gz")
source_aarch64=("${url}/releases/download/${pkgver}/portainer-${pkgver}-linux-arm64.tar.gz")
source_armv6h=("${url}/releases/download/${pkgver}/portainer-${pkgver}-linux-arm.tar.gz")
source_armv7h=("${url}/releases/download/${pkgver}/portainer-${pkgver}-linux-arm.tar.gz")
sha256sums=('6084891b03f8985d087b0fce2240766e919ebf0b7f385c0a41b02176585cd270'
'8cb50d80f1463cef0a907b7f26ec6387b792182959f51f8cd19dcb6f955b886e'
'82f7fca2af76e52147397c3b7b07091b72c1be7c82da6bc47e53001306759635'
'9586395bdf2e21b0b293c397f1b7e45d9493695bbe2fa82c9ec09c32fff13353')
sha256sums_armv6h=('c258c5ca66c252e1dbdc945e1d336e54db8ed6e49b6dddf38407c1851b16e38d')
sha256sums_armv7h=('c258c5ca66c252e1dbdc945e1d336e54db8ed6e49b6dddf38407c1851b16e38d')
sha256sums_aarch64=('eee4f7f05f519a77652bebaff77e0f230f3b276945b70766d28f15b1f20eeb3b')
sha256sums_x86_64=('47b4f73a36c4e7bafb7bcb7f190b284a6176faa2e843631c525b91f31c052663')
package() {
install -Dm644 "${srcdir}/portainer-${pkgver}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
install -Dm755 "${srcdir}/portainer/portainer" "${pkgdir}/usr/bin/portainer"
mkdir -p "${pkgdir}/usr/share/portainer"
cp -rip "${srcdir}/portainer/public" "${pkgdir}/usr/share/portainer/public"
install -Dm644 "portainer.png" "${pkgdir}/usr/share/icons/hicolor/scalable/apps/portainer.png"
install -Dm644 "portainer.desktop" "${pkgdir}/usr/share/applications/portainer.desktop"
install -Dm644 "portainer.service" "${pkgdir}/usr/lib/systemd/system/portainer.service"
ln -s "/usr/lib/docker/cli-plugins/docker-compose" "${pkgdir}/usr/share/portainer/docker-compose"
ln -s "/usr/bin/docker" "${pkgdir}/usr/share/portainer/docker"
}
|