blob: d9732d14879392fea7994f6f1a979bd1b205f0aa (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# Maintainer: Ben Brooks <ben@bbrks.me>
# PRs/Issues: https://github.com/bbrks/aur-portainer-bin
pkgname=portainer-bin
pkgver=2.19.4
pkgrel=1
epoch=2
pkgdesc="A lightweight docker management UI"
arch=('armv6h' 'armv7h' 'aarch64' 'x86_64')
url="https://github.com/portainer/portainer"
license=('custom:zlib')
provides=('portainer')
conflicts=('portainer')
depends=('docker' 'docker-compose')
optdepends=()
makedepends=()
source=("portainer.service"
"portainer.png"
"portainer.desktop"
"portainer-${pkgver}-src.tar.gz::${url}/archive/${pkgver}.tar.gz")
source_x86_64=("${url}/releases/download/${pkgver}/portainer-${pkgver}-linux-amd64.tar.gz")
source_aarch64=("${url}/releases/download/${pkgver}/portainer-${pkgver}-linux-arm64.tar.gz")
source_armv6h=("${url}/releases/download/${pkgver}/portainer-${pkgver}-linux-arm.tar.gz")
source_armv7h=("${url}/releases/download/${pkgver}/portainer-${pkgver}-linux-arm.tar.gz")
sha256sums=('37274c8bc36ec81eae0307b9c58f1c09b34680fe7cb3cb330f253cbb4f8e704b'
'8cb50d80f1463cef0a907b7f26ec6387b792182959f51f8cd19dcb6f955b886e'
'a70567387c0f182fac2e56e5681a63b3dcf474d618dd357531b844009f73d8c0'
'1793248aeb0d5278fb648041c9cecc48e61ed0dcad402e8e36d7fa08bdb2f62a')
sha256sums_armv6h=('2eb881d09f288a499184db72f782dd1318522530ae2a8232a5bce66227a73606')
sha256sums_armv7h=('2eb881d09f288a499184db72f782dd1318522530ae2a8232a5bce66227a73606')
sha256sums_aarch64=('311f7856e0a2e6ee6aeb0246a3a7f63fc183a590b1c7e01544dbfeccd692b872')
sha256sums_x86_64=('aa281e9b6fc682975fb02a9c8665bfa23f87db7fbb1d9d22957f952be8f148ba')
package() {
install -Dm644 "${srcdir}/portainer-${pkgver}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
install -Dm755 "${srcdir}/portainer/portainer" "${pkgdir}/usr/bin/portainer"
mkdir -p "${pkgdir}/usr/share/portainer"
cp -rip "${srcdir}/portainer/public" "${pkgdir}/usr/share/portainer/public"
install -Dm644 "portainer.png" "${pkgdir}/usr/share/icons/hicolor/scalable/apps/portainer.png"
install -Dm644 "portainer.desktop" "${pkgdir}/usr/share/applications/portainer.desktop"
install -Dm644 "portainer.service" "${pkgdir}/usr/lib/systemd/system/portainer.service"
ln -s "/usr/lib/docker/cli-plugins/docker-compose" "${pkgdir}/usr/share/portainer/docker-compose"
ln -s "/usr/bin/docker" "${pkgdir}/usr/share/portainer/docker"
}
|