blob: 1cf441d2ca5bd921eaa1e406f3d33ba926c1687b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# Maintainer: Ben Brooks <ben@bbrks.me>
# PRs/Issues: https://github.com/bbrks/aur-portainer-bin
pkgname=portainer-bin
pkgver=2.17.1
pkgrel=1
epoch=1
pkgdesc="A lightweight docker management UI"
arch=('armv6h' 'armv7h' 'aarch64' 'x86_64')
url="https://github.com/portainer/portainer"
license=('custom:zlib')
provides=('portainer')
conflicts=('portainer')
depends=('docker' 'docker-compose')
optdepends=()
makedepends=()
source=("portainer.service"
"portainer.png"
"portainer.desktop"
"portainer-${pkgver}-src.tar.gz::${url}/archive/${pkgver}.tar.gz")
source_x86_64=("${url}/releases/download/${pkgver}/portainer-${pkgver}-linux-amd64.tar.gz")
source_aarch64=("${url}/releases/download/${pkgver}/portainer-${pkgver}-linux-arm64.tar.gz")
source_armv6h=("${url}/releases/download/${pkgver}/portainer-${pkgver}-linux-arm.tar.gz")
source_armv7h=("${url}/releases/download/${pkgver}/portainer-${pkgver}-linux-arm.tar.gz")
sha256sums=('6084891b03f8985d087b0fce2240766e919ebf0b7f385c0a41b02176585cd270'
'8cb50d80f1463cef0a907b7f26ec6387b792182959f51f8cd19dcb6f955b886e'
'82f7fca2af76e52147397c3b7b07091b72c1be7c82da6bc47e53001306759635'
'364fa771e47513e0a437781dfcde11fb6c0b30758288ff4b5e3937f72dc910e3')
sha256sums_armv6h=('b4ce64e5c91025665074e85d53d0a21c20cea34047f172e0e228b5bf4da1d466')
sha256sums_armv7h=('b4ce64e5c91025665074e85d53d0a21c20cea34047f172e0e228b5bf4da1d466')
sha256sums_aarch64=('aaa3841d6e590c5b6820bbe3f2f36f32530e7ce7ef0dd91ee1ce73001c51e2f1')
sha256sums_x86_64=('ec1a1a7e53481b1e4b19f45249fd7398f390d52646ac740d90f254a3b6a5a096')
package() {
install -Dm644 "${srcdir}/portainer-${pkgver}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
install -Dm755 "${srcdir}/portainer/portainer" "${pkgdir}/usr/bin/portainer"
mkdir -p "${pkgdir}/usr/share/portainer"
cp -rip "${srcdir}/portainer/public" "${pkgdir}/usr/share/portainer/public"
install -Dm644 "portainer.png" "${pkgdir}/usr/share/icons/hicolor/scalable/apps/portainer.png"
install -Dm644 "portainer.desktop" "${pkgdir}/usr/share/applications/portainer.desktop"
install -Dm644 "portainer.service" "${pkgdir}/usr/lib/systemd/system/portainer.service"
ln -s "/usr/lib/docker/cli-plugins/docker-compose" "${pkgdir}/usr/share/portainer/docker-compose"
ln -s "/usr/bin/docker" "${pkgdir}/usr/share/portainer/docker"
}
|