blob: 5a53ccdf9687cfa9e8c6da359c0cde2ab0c33c8e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
|
# Maintainer: Christoph Brill <aur@christophbrill.de>
# Contributor: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor: Dan McGee <dan@archlinux.org>
pkgname=postgresql-11-upgrade
pkgver=11.21
_majorver=${pkgver%.*}
pkgrel=1
pkgdesc='PostgreSQL build for migrating between major versions with pg_upgrade'
url='https://www.postgresql.org/'
arch=('x86_64')
license=('custom:PostgreSQL')
depends=("postgresql-libs>=${_majorver}" 'libxml2' 'openssl>=1.0.0' 'pam'
'zlib' 'icu' 'systemd-libs' 'libldap' 'krb5' 'llvm-libs')
makedepends=('python' 'perl' 'tcl>=8.6.0' 'systemd' 'llvm' 'clang')
optdepends=('python: for PL/Python 3 support'
'perl: for PL/Perl support'
'tcl: for PL/Tcl support')
options=('debug')
source=(https://ftp.postgresql.org/pub/source/v${pkgver}/postgresql-${pkgver}.tar.bz2)
md5sums=('8d0c4236a5879bd3a988d024607cb5c7')
sha256sums=('07b0837471d5dd77b25166b34718f3ba10816b6ad61e691e6fc547cf3fcff850')
b2sums=('a20440904a6908ee1a91bf5c300b15abd2135de01300f2910abe573ba1c52aa6195c81497326c8f1edd5f1b21a993a911a9e78900720ee10e0b311455143c63e')
# Upstream provides md5 and sha256
build() {
cd postgresql-${pkgver}
local configure_options=(
--prefix=/opt/pgsql-${_majorver}
--with-gssapi
--with-libxml
--with-openssl
--with-perl
--with-python
--with-tcl
--with-pam
--without-readline
--with-system-tzdata=/usr/share/zoneinfo
--with-uuid=e2fs
--with-icu
--with-systemd
--with-ldap
--with-llvm
--without-libxslt
--disable-nls
--enable-thread-safety
--enable-rpath
)
# Fix static libs
CFLAGS+=" -ffat-lto-objects"
./configure "${configure_options[@]}"
make -C src all
make -C contrib all
}
package() {
cd postgresql-${pkgver}
# install
make -C src DESTDIR="${pkgdir}" install
make -C contrib DESTDIR="${pkgdir}" install
install -Dm 644 COPYRIGHT -t "${pkgdir}/usr/share/licenses/${pkgname}"
}
# vim: ts=2 sw=2 et:
|