blob: ddb44e6fadd2d6c6e294f29b4132535094f74008 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# derived from postsrsd-git PKGBUILD maintained by
# Radek Podgorny <radek@podgorny.cz>
# Thomas Haider <t.haider@deprecate.de>
# maintainer: fordprefect <fordprefect@dukun.de>
pkgname=postsrsd
pkgver=1.5
pkgrel=2
pkgdesc="Provides the Sender Rewriting Scheme (SRS) via TCP-based lookup tables for Postfix"
arch=('i686' 'x86_64' 'armv7h')
depends=('glibc')
makedepends=('cmake' 'help2man')
backup=('etc/postsrsd/postsrsd')
url="https://github.com/roehling/postsrsd"
install=postsrsd.install
license=(GPL2)
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/roehling/postsrsd/archive/${pkgver}.tar.gz"
"postsrsd.conf")
md5sums=('e33826a7d1055080854ff7db71641fb8'
'81a5eea5b84f3a2de9ad4713512175f0')
build() {
cd "$srcdir/postsrsd-$pkgver"
[[ -d build ]] && rm -rf build
mkdir build
cd build
cmake .. -DCMAKE_INSTALL_PREFIX=/usr -DCMAKE_BUILD_TYPE=Release -DGENERATE_SRS_SECRET=OFF -DCONFIG_DIR=/etc/postsrsd
make all
}
package() {
cd "$srcdir/postsrsd-$pkgver/build"
make DESTDIR="$pkgdir/" install
install -Dm644 "$srcdir/postsrsd.conf" "$pkgdir/usr/lib/sysusers.d/postsrsd.conf"
#rm -rf $pkgdir/usr/lib
mv "$pkgdir/usr/sbin" "$pkgdir/usr/bin"
sed -e 's/^\(RUN_AS=\)nobody/#\1postsrsd/;s/\(\/etc\/postsrsd\)\(\.secret\)/\1\/postsrsd\2/' \
-e 's/^\(# is \).*$/\1localhost\.localdomain/'< postsrsd.default > "$pkgdir/etc/postsrsd/postsrsd"
mkdir -p "$pkgdir/usr/lib/systemd/system"
mv "$pkgdir/etc/systemd/system/postsrsd.service" "$pkgdir/usr/lib/systemd/system/"
}
|