summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 7b6dfb7691bebd46d36f051c6928a02eb4f35edc (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
# Maintainer: Eduardo Sánchez Muñoz (eduardosm)
# Contributor: Sebastien Chassot (sinux) <seba.ptl@sinux.net>

pkgname=pothos
pkgver=0.6.0
pkgrel=2
pkgdesc="The Pothos data-flow framework"
arch=('i686' 'x86_64')
url="https://github.com/pothosware/PothosCore/wiki"
license=('boost')
depends=('python' 'poco' 'soapysdr-git' 'portaudio')
makedepends=('git' 'nlohmann-json')
source=("git+https://github.com/pothosware/PothosCore.git#tag=pothos-$pkgver")
sha256sums=('SKIP')

prepare() {
    cd "$srcdir/PothosCore"
    git submodule update --init --recursive
}

build() {
    mkdir -p "$srcdir/pothos-build"
    cd "$srcdir/pothos-build"
    cmake \
        -DCMAKE_BUILD_TYPE=Release \
        -DCMAKE_INSTALL_PREFIX=/usr \
        "$srcdir/PothosCore"
    make
}

package() {
    cd "$srcdir/pothos-build"
    make DESTDIR="$pkgdir" install
}