blob: 40e0f09c6a559a6bf9e354060287b5296a3b7553 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: Florian Pelz <pelzflorian at pelzflorian.de>
pkgname=potool-renamed
pkgver=0.16
pkgrel=1
pkgdesc="Program to help editing po files, without poedit name clash"
arch=('i686' 'x86_64')
url="http://marcin.owsiany.pl/potool-page"
license=('GPL')
depends=('perl' 'glib2')
provides=('potool')
conflicts=('potool')
source=("http://marcin.owsiany.pl/potool/potool-${pkgver}.tar.gz"
'poedit-rename.patch'
'poedit-test.patch')
sha256sums=('7cf5990f5c60ded21b342b1917731eb75fb12b0762cf639fa9c6f0823d0e08da'
'b331dde0a64ddac275ce607fe6fff8517b692bb186e2c0ea6ff907acbcb604be'
'fed991e63843b265da85708bc3ce75329e5ead0193e73d0527961122bcd43b3b')
prepare() {
cd potool-"$pkgver"
mv scripts/poedit scripts/potooledit
patch -i "$srcdir"/poedit-rename.patch
patch -p0 -i "$srcdir"/poedit-test.patch
}
build() {
cd potool-"$pkgver"
make
}
check() {
cd potool-"$pkgver"
make check
}
package() {
cd "$srcdir"/potool-"$pkgver"
make DESTDIR="$pkgdir/usr" install
install -Dm644 change-po-charset.1 "$pkgdir"/usr/share/man/man1/change-po-charset.1
install -Dm644 change-po-charset.pl.1 "$pkgdir"/usr/share/man/pl/man1/change-po-charset.1
install -Dm644 poedit.1 "$pkgdir"/usr/share/man/man1/potooledit.1
install -Dm644 poedit.pl.1 "$pkgdir"/usr/share/man/pl/man1/potooledit.1
install -Dm644 postats.1 "$pkgdir"/usr/share/man/man1/postats.1
install -Dm644 postats.pl.1 "$pkgdir"/usr/share/man/pl/man1/postats.1
install -Dm644 potool.1 "$pkgdir"/usr/share/man/man1/potool.1
install -Dm644 potool.pl.1 "$pkgdir"/usr/share/man/pl/man1/potool.1
}
|