blob: 489f4d1c1a2c9c3a3da4628d0f36e4479943564f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: Jake <aur@ja-ke.tech>
### Based on extra/powerdevil:
# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Maintainer: Antonio Rojas <arojas@archlinux.org>
# Contributor: Andrea Scarpino <andrea@archlinux.org>
pkgname=powerdevil-ddcutil
_pkgname=${pkgname%-ddcutil}
pkgver=5.22.5
pkgrel=1
pkgdesc='Power management for KDE plasma with DDC/CI enabled'
arch=(x86_64)
url='https://kde.org/plasma-desktop/'
license=(LGPL)
conflicts=($_pkgname)
provides=($_pkgname)
depends=(plasma-workspace bluez-qt networkmanager-qt ddcutil)
makedepends=(extra-cmake-modules kdoctools)
optdepends=('kinfocenter: for the Energy Information KCM')
groups=(plasma)
source=(https://download.kde.org/stable/plasma/$pkgver/$_pkgname-$pkgver.tar.xz{,.sig}
'45-ddcutil-i2c.rules'
'i2c.sysusers')
sha256sums=('597301e6520c17131c98a98960a1e3b7827e63ab9efed0fea5340203133f1c9f'
'SKIP'
'aa9980b02beb49e0ccafc59c57fc6b28b31308e60559120697a864a511fbef6c'
'bf5ee4f9876505628c5ce84e84e918c70d66be70b766d62bb138e294608ffbae')
validpgpkeys=('2D1D5B0588357787DE9EE225EC94D18F7F05997E' # Jonathan Riddell <jr@jriddell.org>
'0AAC775BB6437A8D9AF7A3ACFE0784117FBCE11D' # Bhushan Shah <bshah@kde.org>
'D07BD8662C56CB291B316EB2F5675605C74E02CF' # David Edmundson <davidedmundson@kde.org>
'1FA881591C26B276D7A5518EEAAF29B42A678C20') # Marco Martin <notmart@gmail.com>
build() {
cmake -B build -S $_pkgname-$pkgver \
-DCMAKE_INSTALL_LIBEXECDIR=lib \
-DBUILD_TESTING=OFF \
-DHAVE_DDCUTIL=On
cmake --build build
}
package() {
DESTDIR="$pkgdir" cmake --install build
install -Dm644 '45-ddcutil-i2c.rules' "$pkgdir/usr/lib/udev/rules.d/45-ddcutil-i2c.rules"
install -Dm644 'i2c.sysusers' "$pkgdir/usr/lib/sysusers.d/i2c.conf"
}
|