blob: edd068e49e40c469ae5a7660552f1a8eeeee2be2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
# Maintainer: Anatol Pomozov <anatol.pomozov@gmail.com>
_target=powerpc64-linux-gnu
pkgname=$_target-binutils
pkgver=2.41
pkgrel=2
pkgdesc='A set of programs to assemble and manipulate binary and object files for the PPC64 target'
arch=(x86_64)
url='https://www.gnu.org/software/binutils/'
license=(GPL)
depends=(zlib libelf)
source=(https://ftp.gnu.org/gnu/binutils/binutils-$pkgver.tar.bz2{,.sig})
sha1sums=('b180faf37b6e1c321d6ccbbf66194f17f7acf47c'
'SKIP')
sha256sums=('a4c4bec052f7b8370024e60389e194377f3f48b56618418ea51067f67aaab30b'
'SKIP')
validpgpkeys=('3A24BC1E8FB409FA9F14371813FCEF89DD9E3C4F') # Nick Clifton (Chief Binutils Maintainer) <nickc@redhat.com>
prepare() {
cd binutils-$pkgver
sed -i "/ac_cpp=/s/\$CPPFLAGS/\$CPPFLAGS -O2/" libiberty/configure
}
build() {
cd binutils-$pkgver
if [ "${CARCH}" != "i686" ];
then
# enabling gold linker at i686 makes the install fail
enable_gold='--enable-gold'
fi
echo $CC
echo $CXX
./configure --target=$_target \
--with-sysroot=/usr/$_target \
--prefix=/usr \
--disable-multilib \
--with-gnu-as \
--with-gnu-ld \
--disable-nls \
--enable-ld=default \
$enable_gold \
--enable-plugins \
--enable-deterministic-archives
make
}
check() {
cd binutils-$pkgver
# unset LDFLAGS as testsuite makes assumptions about which ones are active
# do not abort on errors - manually check log files
make -k LDFLAGS="" check || true
}
package() {
cd binutils-$pkgver
make DESTDIR="$pkgdir" install
# Remove file conflicting with host binutils and manpages for MS Windows tools
rm -f "$pkgdir"/usr/share/man/man1/$_target-{dlltool,windres,windmc}*
rm -f "$pkgdir"/usr/lib/bfd-plugins/libdep.so
rm -f "$pkgdir"/usr/etc/gprofng.rc
rm -rf "$pkgdir"/usr/include
rm -rf "$pkgdir"/usr/lib/gprofng/
# Remove info documents that conflict with host version
rm -rf "$pkgdir"/usr/share/info
}
|