blob: 25e26d1ff93d7b15193e40a75793dce90c74b751 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
|
# Maintainer:
# Contributor: David Wu <xdavidwuph@gmail.com>
# Contributor: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor: Ben Reedy <thebenj88@gmail.com>
# Contributor: Clement Guerin <geecko.dev@free.fr>
# Contributor: Thiago Kenji Okada <thiago.mast3r@gmail.com>
# Contributor: uberushaximus <uberushaximus@gmail.com>
pkgname=(
ppsspp-git
ppsspp-assets-git
)
pkgver=1.17.1.r91.746696ab
pkgrel=1
pkgdesc='A PSP emulator written in C++'
arch=(x86_64 aarch64)
url=https://www.ppsspp.org/
license=(GPL2)
makedepends=(
clang
cmake
git
glew
glu
libglvnd
libpng
libzip
ninja
python
qt5-base
qt5-multimedia
qt5-tools
sdl2
sdl2_ttf
snappy
zlib
)
options=(!lto)
source=(
git+https://github.com/hrydgard/ppsspp.git
ppsspp-sdl.desktop
ppsspp-qt.desktop
)
b2sums=('SKIP'
'c6bcdfedee866dfdcc82a8c333c31ff73ed0beec65b63acec8bc8186383c0bc9f0912f21bb9715b665e8dc1793b1a85599761f9037856fa54ad8aa3bfdbfd468'
'328e2ba47b78d242b0ec6ba6bfa039c77a36d1ef7246e5c2c2432d8e976e9360baf505eb05f48408ede1a30545cbbb7f875bf5ebd0252cef35523d449b8254a0')
pkgver() {
cd ppsspp
git describe --tags | sed 's/^v//; s/-/.r/; s/-g/./'
}
prepare() {
cd ppsspp
git remote set-url origin https://github.com/hrydgard/ppsspp.git
git submodule update --init --filter=tree:0 --recursive
}
build() {
export CC=clang
export CXX=clang++
# Rebuild ffmpeg locally
pushd ppsspp/ffmpeg
case "$CARCH" in
x86_64)
./linux_x86-64.sh
;;
aarch64)
./linux_arm64_native.sh
;;
esac
popd
cmake -S ppsspp -B build-sdl -G Ninja \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_SKIP_RPATH=ON \
-DHEADLESS=ON \
-DOpenGL_GL_PREFERENCE=GLVND \
-DUSE_SYSTEM_FFMPEG=OFF \
-DUSE_SYSTEM_MINIUPNPC=OFF \
-DUSE_SYSTEM_LIBZIP=ON \
-DUSE_SYSTEM_SNAPPY=ON \
-DUSE_SYSTEM_ZSTD=ON \
-DUSING_QT_UI=OFF \
-Wno-dev
cmake --build build-sdl -v
cmake -S ppsspp -B build-qt -G Ninja \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_SKIP_RPATH=ON \
-DHEADLESS=OFF \
-DOpenGL_GL_PREFERENCE=GLVND \
-DUSE_SYSTEM_FFMPEG=OFF \
-DUSE_SYSTEM_MINIUPNPC=OFF \
-DUSE_SYSTEM_LIBZIP=ON \
-DUSE_SYSTEM_SNAPPY=ON \
-DUSE_SYSTEM_ZSTD=ON \
-DUSING_QT_UI=ON \
-Wno-dev
cmake --build build-qt -v
}
package_ppsspp-git() {
depends=(
fontconfig
gcc-libs
glew
glibc
hicolor-icon-theme
libgl
libpng
libzip
ppsspp-assets-git
qt5-base
qt5-multimedia
sdl2
sdl2_ttf
snappy
zlib
zstd
)
provides=(ppsspp)
conflicts=(ppsspp)
install -Dm 755 build-sdl/PPSSPPSDL -t "${pkgdir}"/usr/bin/
install -Dm 755 build-sdl/PPSSPPHeadless -t "${pkgdir}"/usr/bin/
install -Dm 755 build-qt/PPSSPPQt -t "${pkgdir}"/usr/bin/
install -dm 755 "${pkgdir}"/usr/share/icons
cp -dr --no-preserve=ownership ppsspp/icons/hicolor "${pkgdir}"/usr/share/icons/
install -Dm 644 ppsspp/icons/icon-512.svg "${pkgdir}"/usr/share/pixmaps/ppsspp.svg
install -Dm 644 ppsspp-sdl.desktop -t "${pkgdir}"/usr/share/applications/
install -Dm 644 ppsspp-qt.desktop -t "${pkgdir}"/usr/share/applications/
}
package_ppsspp-assets-git() {
provides=(ppsspp-assets)
conflicts=(ppsspp-assets)
install -dm 755 "${pkgdir}"/usr/share/ppsspp
cp -dr --no-preserve=ownership build-sdl/assets "${pkgdir}"/usr/share/ppsspp/
}
# vim: ts=2 sw=2 et:
|