blob: d0218aba15ec5925a1fa23fbac1824a06bb23aac (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Maintainer: Valentina Schüller <valentina.schueller@mailbox.org>
# Contributor: Carlos Aznarán <caznaranl@uni.pe>
# Contributor: Florian Lindner <florian.lindner@xgm.de>
pkgname=precice
pkgver=3.1.1
pkgrel=1
pkgdesc="A Coupling Library for Partitioned Multi-Physics Simulations on Massively Parallel Systems"
arch=(x86_64)
url="https://${pkgname}.org"
license=(LGPL-3.0-or-later)
depends=(boost libxml2 openmpi petsc python-numpy)
conflicts=(petsc-complex)
makedepends=(cmake eigen gcc-fortran)
optdepends=('man-db: manual pages for precice-tools'
'git: for Git Revision Info support')
source=(${pkgname}-${pkgver}.tar.gz::https://github.com/${pkgname}/${pkgname}/archive/v${pkgver}.tar.gz)
sha512sums=('3e5837308e2009b6387182a93eaadf43fe276958029cb66b24e5fe532ade2597dabe525ea1cef298b75fd24b93325591b0b946d253128199c8e710e3e96e8f70')
build() {
cmake \
-S ${pkgname}-${pkgver} \
-B build \
-DCMAKE_BUILD_TYPE=None \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_CXX_STANDARD=17 \
-DBUILD_SHARED_LIBS=ON \
-DPRECICE_FEATURE_MPI_COMMUNICATION=ON \
-DPRECICE_FEATURE_PETSC_MAPPING=ON \
-DPRECICE_FEATURE_PYTHON_ACTIONS=ON \
-DPRECICE_CONFIGURE_PACKAGE_GENERATION=ON \
-DPRECICE_FEATURE_GINKGO_MAPPING=OFF \
-DPRECICE_BINDINGS_C=ON \
-DPRECICE_BINDINGS_FORTRAN=ON \
-DPRECICE_BUILD_TOOLS=ON \
-Wno-dev
cmake --build build
}
# check() {
# ctest --test-dir build
# }
package() {
DESTDIR="${pkgdir}" cmake --build build --target install
install -Dm 644 ${pkgname}-${pkgver}/LICENSE -t ${pkgdir}/usr/share/licenses/${pkgname}
install -Dm 644 ${pkgname}-${pkgver}/docs/man/man1/${pkgname}-tools.1 -t ${pkgdir}/usr/share/man/man1
cd "${pkgdir}"
rm -r usr/share/lintian
}
|