PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65

# Maintainer: zxp19821005 <zxp19821005 at 163 dot com>
# Contributor: Ricahrd Neumann aka. Schard <mail ar richard dash neumann period de>
# Contributor: William Brown <glowinthedarkcia@horsefucker.org>
pkgname=processing-bin
_pkgname=Processing
pkgver=4.3
pkgrel=4
arch=("x86_64")
pkgdesc="Programming environment for creating images, animations and interactions."
url="https://processing.org/"
_ghurl="https://github.com/processing/processing4"
license=("custom")
conflicts=("${pkgname%-bin}")
provides=("${pkgname%-bin}=${pkgver}")
options=('!strip')
depends=(
    'libxtst'
    'lib32-libdrm'
    'libx11'
    'libxcursor'
    'lib32-libx11'
    'lib32-mesa'
    'lib32-libxcursor'
    'alsa-lib'
    'mesa'
    'lib32-libxi'
    'hicolor-icon-theme'
    'freetype2'
    'libxrender'
    'lib32-libxrandr'
    'lib32-libxrender'
    'libxxf86vm'
    'libxi'
    'lib32-glibc'
    'libxrandr'
    'lib32-libxxf86vm'
    'libdrm'
    'libxext'
    'java-runtime'
)
source=(
    "${pkgname%-bin}-${pkgver}.tgz::${_ghurl}/releases/download/${pkgname%-bin}-1293-${pkgver}/${pkgname%-bin}-${pkgver}-linux-x64.tgz"
    "LICENSE-${pkgver}.md::https://raw.githubusercontent.com/processing/processing4/${pkgname%-bin}-1293-${pkgver}/LICENSE.md"
)
sha256sums=('3f655b3076158148e7ca9ac94a380d35b925436a5829e9d653715a3146ef3e33'
            '4b7b429609d77db38b2b2ab54065324622dfe85bc6f0db331c13951b44c1cb27')
build() {
    cp "${srcdir}/${pkgname%-bin}-${pkgver}/lib/desktop.template" "${srcdir}/${pkgname%-bin}.desktop"
    sed "s|<BINARY_LOCATION>|${pkgname%-bin}|g;s|<ICON_NAME>|${pkgname%-bin}|g" -i "${srcdir}/${pkgname%-bin}.desktop"
    cp "${srcdir}/${pkgname%-bin}.desktop" "${srcdir}/${pkgname%-bin}-java.desktop"
    sed "s|Exec=${pkgname%-bin}|Exec=${pkgname%-bin}-java|g;s|${_pkgname}|${_pkgname}-Java|g" -i "${srcdir}/${pkgname%-bin}-java.desktop"
    chmod 644 "${srcdir}/${pkgname%-bin}-${pkgver}/modes/java/application/launch4j/w32api/"*
}
package() {
    install -Dm755 -d "${pkgdir}/"{opt/"${pkgname%-bin}",usr/bin}
    cp -r "${srcdir}/${pkgname%-bin}-${pkgver}/"* "${pkgdir}/opt/${pkgname%-bin}"
    ln -sf "/opt/${pkgname%-bin}/${pkgname%-bin}" "${pkgdir}/usr/bin/${pkgname%-bin}"
    install -Dm644 "${srcdir}/"*.desktop -t "${pkgdir}/usr/share/applications"
    ln -sf "/opt/${pkgname%-bin}/${pkgname%-bin}-java" "${pkgdir}/usr/bin/${pkgname%-bin}-java"
    for _icons in 16x16 32x32 64x64 128x128 256x256 512x512 1024x1024;do
        install -Dm644 "${pkgdir}/opt/${pkgname%-bin}/lib/icons/app-${_icons/x*}.png" \
            "${pkgdir}/usr/share/icons/hicolor/${_icons}/apps/${pkgname%-bin}.png"
    done
    install -Dm644 "${srcdir}/LICENSE-${pkgver}.md" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.md"
}