blob: 8a5c13d5b7fc8c1fb2118b4fb0ee41e7d930a491 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
pkgname=procmon-git
pkgver=2.0.0.0.r0.g1524451
pkgrel=1
pkgdesc="Trace syscall activity tool"
arch=('x86_64')
url="https://github.com/Sysinternals/ProcMon-for-Linux"
license=('MIT')
depends=('glibc' 'clang' 'libedit' 'libelf' 'ncurses' 'sysinternalsebpf' 'zlib' 'zstd')
makedepends=('git' 'cmake' 'llvm' 'sqlite')
checkdepends=('iperf3' 'netperf')
provides=("procmon=$pkgver")
conflicts=('procmon')
source=("git+https://github.com/Sysinternals/ProcMon-for-Linux.git")
sha256sums=('SKIP')
pkgver() {
cd "ProcMon-for-Linux"
_tag=$(git tag -l --sort -v:refname | grep -E '^v?[0-9\.]+$' | head -n1)
_rev=$(git rev-list --count $_tag..HEAD)
_hash=$(git rev-parse --short HEAD)
printf "%s.r%s.g%s" "$_tag" "$_rev" "$_hash" | sed 's/^v//'
}
build() {
cd "ProcMon-for-Linux"
cmake \
-B "_build" \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX="/usr" \
-DCMAKE_INSTALL_LIBDIR="lib" \
./
make -C "_build"
}
check() {
cd "ProcMon-for-Linux"
#make -C "_build" test
}
package() {
cd "ProcMon-for-Linux"
make -C "_build" DESTDIR="$pkgdir" install
install -Dm644 "LICENSE" -t "$pkgdir/usr/share/licenses/procmon"
}
|