blob: cb9d6a3156305ff64c6f916d98dcbf67b9a1e63c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# Maintainer: Heyian <heyian404 AT on DOT me>
# Contributor: graysky <therealgraysky AT proton DOT me>
# Contributor: David Runge <dvzrv@archlinux.org>
pkgname=profile-sync-daemon-git
_pkgname=${pkgname/-git/}
_branch=master
pkgver=6.50.r14.gbdea6f0
pkgrel=1
pkgdesc="Symlinks and syncs browser profile dirs to RAM"
arch=('any')
url="https://github.com/graysky2/profile-sync-daemon"
license=('MIT')
depends=('git' 'bash' 'findutils' 'procps-ng' 'rsync' 'systemd')
optdepends=('zsh-completions: for completion when using zsh'
'fuse-overlayfs: for overlayfs mode')
install="psd.install"
provides=(profile-sync-daemon)
conflicts=(profile-sync-daemon)
source=("git+https://github.com/graysky2/profile-sync-daemon.git#branch=$_branch")
b2sums=('SKIP')
pkgver() {
cd "$_pkgname"
git describe --long --tags --abbrev=7 --exclude='v*[a-zA-Z]*' \
| sed -E 's/^[^0-9]*//;s/([^-]*-g)/r\1/;s/-/./g'
}
build() {
cd "$_pkgname"
make
}
package() {
cd "$_pkgname"
make DESTDIR="$pkgdir/" install
install -vDm 644 MIT "${pkgdir}/usr/share/licenses/${pkgname/}/LICENSE"
install -vDm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname/}"
}
|