blob: 258f764fbbcb764816206681ad9af1e9393e7891 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Maintainer: graysky <graysky AT archlinux DOT us>
pkgname='profile-sync-daemon-git'
_pkgname='profile-sync-daemon'
pkgver=r603.d103baf
pkgrel=1
pkgdesc='Syncs browser profiles to tmpfs reducing SSD/HDD calls and speeding-up browsers.'
arch=('any')
url='https://github.com/graysky2/profile-sync-daemon'
license=('MIT')
depends=('procps-ng' 'rsync' 'systemd' 'findutils')
makedepends=('git')
conflicts=('firefox-sync' 'goanysync' 'go-anysync-git' 'iceweasel-sync'
'tmpfs-store' 'tmpfs-sync' 'user-profile-sync-daemon' 'profile-sync-daemon')
provides=('profile-sync-daemon')
_branch='master'
#_branch='unstable'
source=("git://github.com/graysky2/profile-sync-daemon#branch=$_branch")
backup=('etc/psd.conf')
install=psd.install
sha256sums=('SKIP')
pkgver() {
cd "$srcdir/$_pkgname"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
#echo $(git describe --long | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g').$_branch
}
prepare() {
cd "$srcdir/$_pkgname"
# set version of psd to match pkgver
sed -i "s/@VERSION@/$pkgver/" "$srcdir/$_pkgname/common/profile-sync-daemon.in"
}
build() {
cd "$_pkgname"
make
}
package() {
cd "$_pkgname"
make DESTDIR="$pkgdir" install
install -Dm644 MIT "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|