blob: 1bb1b62ac61f3f20cdb18095b3b03000dee3fe9c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: Jasmin <theblazehen@gmail.com>
pkgname=promptfoo
pkgver=0.121.1
pkgrel=1
pkgdesc="Test and evaluate LLM outputs - AI red teaming, pentesting, and vulnerability scanning"
arch=('x86_64')
url="https://github.com/promptfoo/promptfoo"
license=('MIT')
depends=('nodejs')
options=('!strip')
makedepends=('npm' 'jq')
optdepends=(
'python: for Python providers'
'ollama: for local Ollama models'
)
source=("https://registry.npmjs.org/${pkgname}/-/${pkgname}-${pkgver}.tgz")
noextract=("${pkgname}-${pkgver}.tgz")
sha256sums=('5ab78758737246cc124c25ec178afdccb8a307e609e2122c817038b5496c600d')
package() {
npm install -g --ignore-scripts --cache "${srcdir}/npm-cache" --prefix "${pkgdir}/usr" \
"${srcdir}/${pkgname}-${pkgver}.tgz"
# Non-deterministic race in npm gives 777 permissions to random directories.
# See https://github.com/npm/cli/issues/1103 for details.
find "${pkgdir}/usr" -type d -exec chmod 755 {} +
# npm gives ownership of ALL FILES to build user
# https://bugs.archlinux.org/task/63396
chown -R root:root "${pkgdir}"
# Remove references to pkgdir
find "$pkgdir" -name package.json -print0 | xargs -r -0 sed -i '/_where/d'
# Remove references to srcdir
local tmppackage="$(mktemp)"
local pkgjson="$pkgdir/usr/lib/node_modules/$pkgname/package.json"
jq '.|=with_entries(select(.key|test("_.+")|not))' "$pkgjson" > "$tmppackage"
mv "$tmppackage" "$pkgjson"
chmod 644 "$pkgjson"
# Install license
install -Dm644 "${pkgdir}/usr/lib/node_modules/${pkgname}/LICENSE" \
"${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|