summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 8e4d69268cddc8370fbd5bd88c6fc266f18d5c79 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
# Maintainer: grufo <madmurphy333 at gmail.com>

pkgname=proot-git
_pkgname=proot
_projectname=PRoot
pkgver='r1008.cffb379'
pkgrel=1
pkgdesc="chroot, mount --bind, and binfmt_misc without privilege/setup"
arch=('i686' 'x86_64')
url="http://proot.me"
license=('GPL')
provides=('proot')
conflicts=("proot" "proot-bin")
depends=('talloc')
makedepends=('python-docutils' 'libxslt')
source=("git+https://github.com/proot-me/${_projectname}.git")
sha1sums=('SKIP')

pkgver() {

	cd "${_projectname}"
	printf "'r%s.%s'" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"

}


build() {

	cd "${srcdir}/${_projectname}/src"
	make -f GNUmakefile

	cd "${srcdir}/${_projectname}/doc"
	make -f GNUmakefile

}

package() {

	cd "${srcdir}/${_projectname}"

	install -m755 -d "${pkgdir}"/usr/bin
	install -m755 src/${_pkgname} "${pkgdir}"/usr/bin

	install -m755 -d "${pkgdir}"/usr/share/man/man1/
	install -m644 -T doc/proot/man.1 "${pkgdir}"/usr/share/man/man1/${_pkgname}.1

	install -m755 -d "${pkgdir}"/usr/share/doc/proot/
	install -m644 doc/proot/changelog.txt "${pkgdir}"/usr/share/doc/proot
	install -m644 doc/proot/index.html "${pkgdir}"/usr/share/doc/proot
	install -m644 doc/proot/manual.txt "${pkgdir}"/usr/share/doc/proot
	install -m644 doc/proot/roadmap.txt "${pkgdir}"/usr/share/doc/proot

	install -m755 -d "${pkgdir}"/usr/share/doc/proot/stylesheets
	install -m644 doc/proot/stylesheets/* "${pkgdir}"/usr/share/doc/proot/stylesheets

}