PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66

# Maintainer: Christian Krause ("wookietreiber") <kizkizzbangbang@googlemail.com>

pkgname=proovread
pkgver=2.12
pkgrel=4
pkgdesc="large-scale high accuracy PacBio correction through iterative short read consensus"
arch=('i686' 'x86_64')
url="https://github.com/BioInf-Wuerzburg/proovread"
license=('PerlArtistic')
depends=('blasr-git' 'perl-log-log4perl' 'blast+>=2.2.24' 'samtools>=1.1' 'shrimp')
source=("$pkgname::git+https://github.com/BioInf-Wuerzburg/proovread#tag=proovread-2.12")
md5sums=('SKIP')

prepare() {
  cd $srcdir/$pkgname

  git submodule init
  git submodule update

  sed -e "s|'bwa-path' => \$RealBin.'/../util/bwa/'|'bwa-path' => ''|" \
      -e "s|'shrimp-path' => \$RealBin.'/../util/shrimp-2.2.3/'|'shrimp-path' => ''|" \
      -e "s|'blasr-path' => \$RealBin.'/../util/blasr-1.3.1/'|'blasr-path' => ''|" \
      -i proovread.cfg

  sed -e 's|my $cfg_core_file = "$RealBin/../proovread.cfg";|my $cfg_core_file = "/usr/share/proovread/proovread.cfg";|' \
      -e 's|my $cfg_core_file = "../proovread.cfg";|my $cfg_core_file = "/usr/share/proovread/proovread.cfg";|' \
      -i bin/bam2cns \
         bin/proovread \
         bin/sam2cns \
         bin/test_cfg.pl

  sed -e 's|$RealBin/../sample|/usr/share/proovread/sample|' \
      -i bin/proovread
}

build() {
  cd $srcdir/$pkgname/util/bwa

  make
}

# check() {
#   cd $srcdir/$pkgname/t

#   for testfile in *.t ; do
#     perl $testfile
#   done
# }

package() {
  cd $srcdir/$pkgname

  mkdir -p $pkgdir/usr/bin \
           $pkgdir/usr/lib/perl5/vendor_perl \
           $pkgdir/usr/share/proovread/sample

  for file in bin/* util/SeqChunker/bin/* util/bwa/bwa-proovread ; do
    install -Dm755 $file $pkgdir/usr/bin/$(basename $file .pl)
  done

  cp -r lib/* $pkgdir/usr/lib/perl5/vendor_perl

  install -Dm644 proovread.cfg $pkgdir/usr/share/proovread/proovread.cfg

  cp sample/* $pkgdir/usr/share/proovread/sample
}