blob: e656d50ba07c14a41f123ef5431f8b020a5a1bd5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
|
# Maintainer: Serge K <arch@phnx47.net>
# For Issues, Pull Requests
# https://github.com/phnx47/pkgbuilds
pkgname="proto"
pkgdesc='A multi-language version and dependency manager'
pkgver=0.9.1
pkgrel=1
license=('MIT')
url='https://github.com/moonrepo/proto'
arch=('x86_64')
depends=('git')
makedepends=('cargo')
options=('!lto')
source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/refs/tags/v${pkgver}.tar.gz")
sha512sums=('4f5dbf8c1a191cec24d5c97ebb16bba572b6fab94dab55e989c27161c2582860d4e111878baa17b819f6db7daa7c1dc84f14898250e6ee7b774108dd84a56db2')
prepare() {
cd "${pkgname}-${pkgver}"
export RUSTUP_TOOLCHAIN="stable"
cargo fetch --locked --target "${CARCH}-unknown-linux-gnu"
}
build() {
cd "${pkgname}-${pkgver}"
export RUSTUP_TOOLCHAIN="stable"
export CARGO_TARGET_DIR="target"
cargo build --release --frozen
}
package() {
cd "${pkgname}-${pkgver}"
install -Dm 755 "target/release/${pkgname}" "${pkgdir}/usr/bin/${pkgname}"
install -Dm 644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|