blob: 4f7c27c9414ac265edfe7ddf643efb8c83d161ff (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Maintainer: Vitalii Kuzhdin <vitaliikuzhdin@gmail.com>
# Contributor: Aliaksandr Mianzhynski <amenzhinsky@gmail.com>
_pkgname="protoc-gen-go"
pkgname="${_pkgname}-git"
pkgver=1.35.1.r1.gd340238
pkgrel=1
pkgdesc="Go support for Google's protocol buffers"
arch=('x86_64' 'aarch64' 'i686')
url="https://github.com/protocolbuffers/protobuf-go"
license=('BSD-3-Clause')
depends=('glibc')
makedepends=('git' 'go')
optdepends=('protobuf: protoc generator')
provides=("${_pkgname}=${pkgver%%.r*}")
conflicts=("${_pkgname}")
_pkgsrc="protobuf-go"
source=("${_pkgsrc}::git+${url}.git")
sha256sums=('SKIP')
pkgver() {
cd "${_pkgsrc}"
git describe --long --tags --abbrev=7 | sed 's/v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd "${srcdir}/${_pkgsrc}"
mkdir -p "build"
}
build() {
cd "${srcdir}/${_pkgsrc}"
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
go build -o "build/${_pkgname}" ./"cmd/${_pkgname}"
}
check() {
cd "${srcdir}/${_pkgsrc}"
go test ./...
}
package() {
cd "${srcdir}/${_pkgsrc}"
install -Dm755 "build/${_pkgname}" "${pkgdir}/usr/bin/${_pkgname}"
install -Dm644 "README.md" "${pkgdir}/usr/share/doc/${_pkgname}/README.md"
install -Dm644 "LICENSE" "${pkgdir}/usr/share/licenses/${_pkgname}/LICENSE"
install -Dm644 "PATENTS" "${pkgdir}/usr/share/licenses/${_pkgname}/PATENTS"
}
|