blob: daf076aaaff23a7ef4711522261315265dc619d7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
|
# Maintainer: Mark Wagie <mark dot wagie at tutanota dot com>
pkgname=protonplus
_app_id=com.vysp3r.ProtonPlus
pkgver=0.3.4
pkgrel=1
pkgdesc="A simple proton version manager"
arch=('x86_64')
url="https://github.com/Vysp3r/ProtonPlus"
license=('GPL3')
depends=('json-glib' 'libadwaita' 'libarchive' 'libsoup3')
makedepends=('meson' 'vala')
checkdepends=('appstream-glib')
source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz")
sha256sums=('873fea4b3c9ccec0f3059efc286f0bdcce43dc09f09cdb4274c8be673217fd9b')
build() {
arch-meson "ProtonPlus-$pkgver" build
meson compile -C build
}
check() {
meson test -C build
cd "ProtonPlus-$pkgver"
appstream-util validate-relax --nonet "data/${_app_id}.appdata.xml"
desktop-file-validate "data/${_app_id}.desktop"
}
package() {
meson install -C build --destdir "$pkgdir"
ln -s "/usr/bin/${_app_id}" "$pkgdir/usr/bin/$pkgname"
}
|