blob: 8d85d659d8cc3ad5ab4ae5dbdb41717247e6b9df (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
# Maintainer: Jorge Pizarro-Callejas <jpizarrocallejas@gmail.com>
pkgname=protonup-qt-git
_app_id=net.davidotek.pupgui2
_pkgname="ProtonUp-Qt"
pkgver=2.13.0.r7.gf881e4c
pkgrel=1
pkgdesc="Install and manage Proton-GE and Luxtorpeda for Steam and Wine-GE for Lutris"
arch=('any')
url="https://davidotek.github.io/protonup-qt"
license=('GPL-3.0-or-later')
depends=(
'pyside6'
'python-inputs'
'python-psutil'
'python-pyaml'
'python-pyxdg'
'python-requests'
'python-steam'
'python-vdf'
'python-zstandard'
'qt6-tools'
)
makedepends=(
'git'
'python-build'
'python-installer'
'python-setuptools'
'python-wheel'
)
checkdepends=(
'appstream'
'desktop-file-utils'
)
optdepends=(
'dosbox: required for Boxtron'
'git: required for SteamTinkerLaunch'
'inotify-tools: required for Boxtron & Roberta'
'scummvm: required for Roberta'
'timidity++: required for Boxtron'
'unzip: required for SteamTinkerLaunch'
'wget: required for SteamTinkerLaunch'
'xdotool: required for SteamTinkerLaunch'
'xorg-xprop: required for SteamTinkerLaunch'
'xorg-xrandr: required for SteamTinkerLaunch'
'xorg-xwininfo: required for SteamTinkerLaunch'
'xxd: required for SteamTinkerLaunch'
'yad: required for SteamTinkerLaunch'
)
source=("git+https://github.com/DavidoTek/$_pkgname")
sha256sums=('SKIP')
provides=(${pkgname%-git})
conflicts=(${pkgname%-git} ${pkgname%-git}-bin)
pkgver() {
cd "${srcdir}/${_pkgname}"
git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "$srcdir/$_pkgname"
python -m build --wheel --no-isolation
}
check() {
cd "$srcdir/$_pkgname"
appstreamcli validate --no-net "share/metainfo/${_app_id}.appdata.xml"
desktop-file-validate "share/applications/${_app_id}.desktop"
}
package() {
cd "$srcdir/$_pkgname"
python -m installer --destdir="$pkgdir" dist/*.whl
cp -r share "$pkgdir/usr/"
ln -s "/usr/bin/${pkgname%-git}" "$pkgdir/usr/bin/${_app_id}"
}
|