blob: 3633566afcfe800c08ee5e5f9bf55d4b27ce132f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: Donald Webster <fryfrog@gmail.com>
# Helpful url: https://prowlarr.servarr.com/v1/update/develop?version=0.0.0.0&os=linux&runtime=netcore&arch=x64
pkgname="prowlarr"
pkgver=0.1.0.451
pkgrel=1
pkgdesc="Movie download automation for usenet and torrents."
arch=('x86_64' 'aarch64' 'armv7h')
url="https://github.com/Prowlarr/Prowlarr"
license=('GPL3')
options=('!strip' 'staticlibs')
depends=('sqlite')
source_x86_64=("prowlarr.develop.${pkgver}.linux-core-x64.tar.gz::https://prowlarr.servarr.com/v1/update/nightly/updatefile?version=${pkgver}&os=linux&runtime=netcore&arch=x64")
source_aarch64=("prowlarr.develop.${pkgver}.linux-core-arm64.tar.gz::https://prowlarr.servarr.com/v1/update/nightly/updatefile?version=${pkgver}&os=linux&runtime=netcore&arch=arm64")
source_armv7h=("prowlarr.develop.${pkgver}.linux-core-arm.tar.gz::https://prowlarr.servarr.com/v1/update/nightly/updatefile?version=${pkgver}&os=linux&runtime=netcore&arch=arm")
source=(
'prowlarr.service'
'prowlarr.tmpfiles'
'prowlarr.sysusers'
'package_info'
)
sha512sums=('bc0df2df010d8e272ff7a1fabc24e2012b87bc260bac79ffd7b3716e38fa9b2fe84c5f8f57b22e1812f702c3809d63086a0586db58ce66bfeeb2a9ad5cffd3ca'
'9159ceda0955f2ebc495dd470c9d6234d8534a120ab81fa58fefae94a8ecfdc8fe883fb1287bc10429e7b4f35ac59d36232d716c161a242a4bfcdff768f1b9a2'
'6ebd6f268e5aa7446e3c77540f5c95b3237959892e8800f5f380a0f979c71ec0d6f7664c1a58f7d10a255bc21a19bad0fef8609b02b4d5e15f340e66364017d2'
'0e305d68b950372ed169f3b89a3b97d3423f968460a11b9620e779444d04227091daaad5a9fcad1c24aa868fc5b39129ba247f4a09d9191292bfd20230f88da2')
sha512sums_x86_64=('606c04b60a9be1b7e8bd9ac608b1013f22fc4fee083f18545a01ee84b99a804fecdf570fb4983e6040591353b63002565c63303e3bcd9012936ad2abfbfac38e')
sha512sums_aarch64=('9263ed3b635ff430870e13cb9b3c38a0565e612755f99e4ad48fbe3a83b7ffdffba938fc0689ca8c01f693312a90be67d8e1dc7086ce799fd26fb53018cab1c2')
sha512sums_armv7h=('1670e8bc0b0dc4860f9da5452a8bd4e84d6d22c4815f13ebbf3a9861bb6402980166eeccb0fab7acaf89c6dbe737dd85a455e14999c47ebdee69673782f748c3')
package() {
rm -rf "${srcdir}/Prowlarr/prowlarr.Update"
install -d -m 755 "${pkgdir}/usr/lib/prowlarr/bin"
cp -dpr --no-preserve=ownership "${srcdir}/Prowlarr/"* "${pkgdir}/usr/lib/prowlarr/bin"
chmod -R a=,a+rX,u+w "${pkgdir}/usr/lib/prowlarr/bin"
chmod +x "${pkgdir}/usr/lib/prowlarr/bin/Prowlarr"
# Disable built in updater.
install -D -m 644 "${srcdir}/package_info" "${pkgdir}/usr/lib/prowlarr"
echo "PackageVersion=${pkgver}-${pkgrel}" >> "${pkgdir}/usr/lib/prowlarr/package_info"
install -D -m 644 "${srcdir}/prowlarr.service" "${pkgdir}/usr/lib/systemd/system/prowlarr.service"
install -D -m 644 "${srcdir}/prowlarr.sysusers" "${pkgdir}/usr/lib/sysusers.d/prowlarr.conf"
install -D -m 644 "${srcdir}/prowlarr.tmpfiles" "${pkgdir}/usr/lib/tmpfiles.d/prowlarr.conf"
}
|