blob: 091573b0f4e7846c2c81b0741c564df09c83347c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: Donald Webster <fryfrog@gmail.com>
# Helpful url: https://prowlarr.servarr.com/v1/update/develop?version=0.0.0.0&os=linux&runtime=netcore&arch=x64
pkgname="prowlarr"
pkgver=0.1.0.325
pkgrel=1
pkgdesc="Movie download automation for usenet and torrents."
arch=('x86_64' 'aarch64' 'armv7h')
url="https://github.com/Prowlarr/Prowlarr"
license=('GPL3')
options=('!strip' 'staticlibs')
depends=('sqlite')
source_x86_64=("prowlarr.develop.${pkgver}.linux-core-x64.tar.gz::https://prowlarr.servarr.com/v1/update/nightly/updatefile?version=${pkgver}&os=linux&runtime=netcore&arch=x64")
source_aarch64=("prowlarr.develop.${pkgver}.linux-core-arm64.tar.gz::https://prowlarr.servarr.com/v1/update/nightly/updatefile?version=${pkgver}&os=linux&runtime=netcore&arch=arm64")
source_armv7h=("prowlarr.develop.${pkgver}.linux-core-arm.tar.gz::https://prowlarr.servarr.com/v1/update/nightly/updatefile?version=${pkgver}&os=linux&runtime=netcore&arch=arm")
source=(
'prowlarr.service'
'prowlarr.tmpfiles'
'prowlarr.sysusers'
'package_info'
)
sha512sums=('bc0df2df010d8e272ff7a1fabc24e2012b87bc260bac79ffd7b3716e38fa9b2fe84c5f8f57b22e1812f702c3809d63086a0586db58ce66bfeeb2a9ad5cffd3ca'
'9159ceda0955f2ebc495dd470c9d6234d8534a120ab81fa58fefae94a8ecfdc8fe883fb1287bc10429e7b4f35ac59d36232d716c161a242a4bfcdff768f1b9a2'
'6ebd6f268e5aa7446e3c77540f5c95b3237959892e8800f5f380a0f979c71ec0d6f7664c1a58f7d10a255bc21a19bad0fef8609b02b4d5e15f340e66364017d2'
'0e305d68b950372ed169f3b89a3b97d3423f968460a11b9620e779444d04227091daaad5a9fcad1c24aa868fc5b39129ba247f4a09d9191292bfd20230f88da2')
sha512sums_x86_64=('5769b50759cbd3069e33b5352bad2a4fbdc3fd3bbd753d902052529efa6b2f4aee169951c2260b76ea0a0c982ec365a430c776e7db56fcf5cb0ff9cdcf8e5f0f')
sha512sums_aarch64=('d2bf7f025d479d477f2e22bc39cd55f3b74dd7f9abc371e1827be84ad42e0ac913dd5a775064a9a6616efadc259e7a91a13a0c36df92f5b95bd897f741a333f4')
sha512sums_armv7h=('60a06977f424d676af49178ad2aa969c28dc1c47c15fa443f323714f2728681b79c887e72b530bd8e0d4fcdd842e08fc72239e099bd33d7e88124331452572dc')
package() {
rm -rf "${srcdir}/Prowlarr/prowlarr.Update"
install -d -m 755 "${pkgdir}/usr/lib/prowlarr/bin"
cp -dpr --no-preserve=ownership "${srcdir}/Prowlarr/"* "${pkgdir}/usr/lib/prowlarr/bin"
chmod -R a=,a+rX,u+w "${pkgdir}/usr/lib/prowlarr/bin"
chmod +x "${pkgdir}/usr/lib/prowlarr/bin/Prowlarr"
# Disable built in updater.
install -D -m 644 "${srcdir}/package_info" "${pkgdir}/usr/lib/prowlarr"
echo "PackageVersion=${pkgver}-${pkgrel}" >> "${pkgdir}/usr/lib/prowlarr/package_info"
install -D -m 644 "${srcdir}/prowlarr.service" "${pkgdir}/usr/lib/systemd/system/prowlarr.service"
install -D -m 644 "${srcdir}/prowlarr.sysusers" "${pkgdir}/usr/lib/sysusers.d/prowlarr.conf"
install -D -m 644 "${srcdir}/prowlarr.tmpfiles" "${pkgdir}/usr/lib/tmpfiles.d/prowlarr.conf"
}
|