blob: 21140d465dbde540c3de23fd78334489d1ff8c17 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Maintainer: Donald Webster <fryfrog@gmail.com>
# Helpful url: https://prowlarr.servarr.com/v1/update/develop?version=0.0.0.0&os=linux&runtime=netcore&arch=x64
pkgname="prowlarr-nightly"
pkgver=1.16.0.4364
pkgrel=1
pkgdesc="Usenet and torrent aggregator, similar to nzbhydra2 and jackett."
arch=('x86_64' 'aarch64' 'armv7h')
url="https://github.com/Prowlarr/Prowlarr"
license=('GPL3')
options=('!strip' 'staticlibs')
depends=('sqlite')
optdepends=(
'sonarr: automatically adds and remove indexers/trackers'
'radarr: automatically adds and remove indexers/trackers'
'lidarr: automatically adds and remove indexers/trackers'
'readarr: automatically adds and remove indexers/trackers'
)
provides=('prowlarr')
conflicts=('prowlarr')
source_x86_64=("prowlarr.develop.${pkgver}.linux-core-x64.tar.gz::https://prowlarr.servarr.com/v1/update/nightly/updatefile?version=${pkgver}&os=linux&runtime=netcore&arch=x64")
source_aarch64=("prowlarr.develop.${pkgver}.linux-core-arm64.tar.gz::https://prowlarr.servarr.com/v1/update/nightly/updatefile?version=${pkgver}&os=linux&runtime=netcore&arch=arm64")
source_armv7h=("prowlarr.develop.${pkgver}.linux-core-arm.tar.gz::https://prowlarr.servarr.com/v1/update/nightly/updatefile?version=${pkgver}&os=linux&runtime=netcore&arch=arm")
source=(
'prowlarr.service'
'prowlarr.tmpfiles'
'prowlarr.sysusers'
'package_info'
)
sha512sums=('66a0fa8cdfb6119db300bb00bdead9c472776e8d5175fd313039116de4ed5b761ed13973229393106519e6ed4a45ec9709bd2c6099cd655448c5a1af2baf7b89'
'9159ceda0955f2ebc495dd470c9d6234d8534a120ab81fa58fefae94a8ecfdc8fe883fb1287bc10429e7b4f35ac59d36232d716c161a242a4bfcdff768f1b9a2'
'6ebd6f268e5aa7446e3c77540f5c95b3237959892e8800f5f380a0f979c71ec0d6f7664c1a58f7d10a255bc21a19bad0fef8609b02b4d5e15f340e66364017d2'
'473f38f922c1c24987bc77bb687739e3de0eed5c567407c690e0e9ac1604479bbe4f606ccb804067dbe97a100a748b4c2e05a11e30835d42e67ec65177a4f42a')
sha512sums_x86_64=('01bdaaaeed4c54e4bb7116dd174740469c6cd16d621ae562b0653374f8709f68a6cb9f274e904a8c0faf7c8681bcacd9fa99535d2309e3af8e3d1f30480d2aa7')
sha512sums_aarch64=('7a45728f4d6f8e6b60efe94839c279f7e7fcb4be7fefa85bf7a87aba74f2db42bc7270bcbc73b6f884dbba78191f1beed47569e4810e3cc74ce90ddabaf11315')
sha512sums_armv7h=('8c7e97b6d890da83806b363363b6c050b9e6bda7d9f876b71d30cf2f7dad6b485ac21e7b9015a6f5510b657438e0287815a76c698ad5bde00c19e4cdc7cd6bc9')
package() {
rm -rf "${srcdir}/Prowlarr/prowlarr.Update"
install -d -m 755 "${pkgdir}/usr/lib/prowlarr/bin"
cp -dpr --no-preserve=ownership "${srcdir}/Prowlarr/"* "${pkgdir}/usr/lib/prowlarr/bin"
chmod -R a=,a+rX,u+w "${pkgdir}/usr/lib/prowlarr/bin"
chmod +x "${pkgdir}/usr/lib/prowlarr/bin/Prowlarr"
# Disable built in updater.
install -D -m 644 "${srcdir}/package_info" "${pkgdir}/usr/lib/prowlarr"
echo "PackageVersion=${pkgver}-${pkgrel}" >> "${pkgdir}/usr/lib/prowlarr/package_info"
install -D -m 644 "${srcdir}/prowlarr.service" "${pkgdir}/usr/lib/systemd/system/prowlarr.service"
install -D -m 644 "${srcdir}/prowlarr.sysusers" "${pkgdir}/usr/lib/sysusers.d/prowlarr.conf"
install -D -m 644 "${srcdir}/prowlarr.tmpfiles" "${pkgdir}/usr/lib/tmpfiles.d/prowlarr.conf"
}
|